Papervision3DTest06　：←　→で方向指定、↑　↓で前進後退のテスト

/**
 * Copyright siouxcitizen ( http://wonderfl.net/user/siouxcitizen )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/kmZq
 */

// forked from hacker_7daxapax's Papervision3DTest03
//←↑→↓またはA、W、D、SボタンでCubeオブジェクトを移動させます
//←　→またはA、Dで方向決定、↑またはWで前進、↓またはSで後退

package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.KeyboardEvent;
 
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.objects.primitives.Arrow;
    import org.papervision3d.materials.WireframeMaterial;
    import org.papervision3d.view.Viewport3D;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.render.BasicRenderEngine;
 
    [SWF(width="500", height="500", frameRate="60", backgroundColor="#111111")]
 
    public class MovieCube extends Sprite
    {
        private var container    : Sprite;
        private var viewport     : Viewport3D;
        private var scene        : Scene3D;
        private var camera       : Camera3D;
        private var wireFramMate : WireframeMaterial;
        private var planeObj     : Plane;
        private var arrowObj     : Arrow;
        private var renderer     : BasicRenderEngine;

        private var planeSize : int = 2000;//Planeオブジェクト1辺の長さ

        //MoviePlaneクラスのコンストラクタ
        public function MovieCube():void
        {          
            //ビューポート生成
            viewport = new Viewport3D(stage.stageWidth, stage.stageHeight);
            addChild(viewport);

            //シーン生成
            scene = new Scene3D();

            //レンダリングエンジン生成
            renderer = new BasicRenderEngine();

            //Planeオブジェクト用ワイヤーフレームマテリアル設定
            wireFramMate = new WireframeMaterial(0xFF0000);

            //Planeオブジェクト生成
            planeObj= new Plane(wireFramMate, planeSize, planeSize, 4, 4);
            planeObj.rotationX = 90;
            scene.addChild(planeObj);
            
            //Arrowオブジェクト生成
            arrowObj = new Arrow();
            arrowObj.y = 50;
            scene.addChild(arrowObj);
            
            //カメラ設定
            camera = new Camera3D();
            camera.y = arrowObj.y + 300;
 
            //イベント処理用リスナを設定
            stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
            stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
        }

        //フレーム毎の処理
        private function onEnterFrame(e:Event):void{
            renderer.renderScene(scene, camera, viewport);
        }
        
        //カメラ視点設定
        private function cameraSet():void{
            camera.x = arrowObj.x;
            camera.y = arrowObj.y + 300;
            camera.z = arrowObj.z - 1000;
        }
        
        //キーボード入力処理
        //←↑→↓、A、W、D、Sボタン押下時処理(Arrowオブジェクト移動処理)
        private function onKeyDown(event:KeyboardEvent):void{
            //←ボタンまたはAボタン 左回転     
            if ((event.keyCode == 37) || (event.keyCode == 65)) {
                arrowObj.rotationY -=5;
            //→ボタンまたはDボタン 右回転
            } else if ((event.keyCode == 39) || (event.keyCode == 68)) {
                arrowObj.rotationY +=5;
            //↑ボタンまたはWボタン 前進
            } else if ((event.keyCode == 38) || (event.keyCode == 87)) {
                arrowObj.moveForward(10); 
            //↓ボタンまたはSボタン 後退
            } else if ((event.keyCode == 40) || (event.keyCode == 83)) {
                arrowObj.moveBackward(5);
            }
            //カメラ視点設定            
            cameraSet();
        }
    }
}