PV3D ライティングテスト

/**
 * Copyright tepe ( http://wonderfl.net/user/tepe )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/zrlr
 */

package {

    import flash.display.Sprite;
    import flash.events.Event;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.lights.PointLight3D;
    import org.papervision3d.view.Viewport3D;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.objects.DisplayObject3D;
    import org.papervision3d.objects.primitives.Sphere;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.materials.shadematerials.FlatShadeMaterial;


    [SWF(backgroundColor="#000000", width="600", height="600", frameRate="30")]

    public class Main extends Sprite {
        // プロパティ
        private var scene:Scene3D;
        private var camera:Camera3D;
        private var light:PointLight3D;//光源
        private var viewport:Viewport3D;
        private var renderer:BasicRenderEngine;
        private var sphere:Sphere;
        private static var radius:uint = 500;
        private var angle:Number = 90;
        private var degree:Number = 0;
        private static var depression:uint = 30;
        private static var radian:Number = Math.PI/180;
        

        // コンストラクタ
        public function Main() {
            init();
        }

        // メソッド
        private function init():void {
            scene = new Scene3D();
            camera =new Camera3D();
            light = new PointLight3D(false);
            viewport = new Viewport3D(0, 0, true, false);
            renderer = new BasicRenderEngine();
            setup();
            initialize();
            addChild(viewport);
            addEventListener(Event.ENTER_FRAME, render, false, 0, true);
        }
        private function setup():void {
            camera.x = 0;
            camera.y = 0;
            camera.z = radius;
            camera.zoom = 25;
            camera.focus = 20;
            camera.target = DisplayObject3D.ZERO;
            //光源位置設定
            light.x = -radius;
            light.y = radius;
            light.z = radius;
        }
        private function initialize():void {
            //マテリアル設定
            var material:FlatShadeMaterial = new FlatShadeMaterial(light, 0xFFFFFF);
            sphere = new Sphere(material, 160, 40, 20);
            scene.addChild(sphere);
        }
        private function render(evt:Event):void {
            //移動
            angle ++;
            degree += 2;
            var dip:Number = depression*Math.sin(degree*radian);
            //カメラと光源の位置を合わせる
            light.x = camera.x = radius*Math.cos(angle*radian)*Math.cos(dip*radian);
            light.y = camera.y = radius*Math.sin(dip*radian);
            light.z = camera.z = radius*Math.sin(angle*radian)*Math.cos(dip*radian);
            //レンダリング
            renderer.renderScene(scene, camera, viewport);
        }

    }

}