Project Euler 138

/**
 * Copyright uwi ( http://wonderfl.net/user/uwi )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/yrTx
 */

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.utils.getTimer;
    // @see http://projecteuler.net/index.php?section=problems&id=138
    public class Euler138 extends Sprite {
        private var _tf : TextField;
  
        public function Euler138() {
            _tf = new TextField();
            _tf.width = 465;
            _tf.height = 465;
            addChild(_tf);
            
            var s : int = getTimer();
            _tf.appendText("" + solve() + "\n");
            var g : int = getTimer();
            _tf.appendText("" + (g - s) + " ms\n");
        }
        
        // bは偶数、かつhは奇数、かつb/2とhは互いに素なので、
        // L=m^2+n^2, b/2=2mn, h=m^2-n^2
        // h=b±1より、bを消去して
        // m^2-4mn-n^2±1=0
        // m=2n+√(5n^2±1)
        // 根号内はn:odd→5n^2-1のみ有効, n:even→5n^2+1のみ有効
        // なのでnをインクリメントしてこれらが平方数かどうかチェックし、そうであればLを求める。
        private function solve() : Number
        {
            var ct : int = 0;
            var sum : Number = 0;
            for(var n : int = 1;ct < 12;n++){
                var m : int;
                var sq : Number;
                sq = Math.sqrt(5 * n * n + (1 - ((n & 1) << 1)));
                if(sq - int(sq) == 0){
                    m = 2 * n + sq;
                }else{
                    continue;
                }
                
                var L : Number = m * m + n * n;
                _tf.appendText("" + L + "\n");
                sum += L;
                ct++;
            }
            return sum;
        }
    }
}