Comparing access speed to get values from the Dictionary and Object classes

/**
 * Copyright Fumio ( http://wonderfl.net/user/Fumio )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/yH5H
 */

package {
	import flash.display.Sprite;
	import flash.display.MovieClip;
	import flash.utils.Dictionary;
	import flash.utils.getTimer;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import flash.text.TextFormatAlign;
	[SWF(width = "240",height = "180")]
	public class Testing_Object_and_Dictionary extends Sprite {
		private const AMOUNT:uint = 100000;
		private var started:uint;
		private var my_txt:TextField = new TextField();
		private var label_txt:TextField = new TextField();
		private var my_fmt:TextFormat = new TextFormat();
		private var instances:Vector.<MovieClip> = new Vector.<MovieClip>();
		private var myDictionary:Dictionary = new Dictionary();
		private var myObject:Object = {};
		public function Testing_Object_and_Dictionary() {
			// Creating a TextField for display
			createTextField();
			// Starting test
			initialize();
			useDynamicVariable();
			useObject();
			useDictionary();
		}
		private function initialize():void {
			for (var i:uint = 0; i < AMOUNT; i++) {
				var _mc:MovieClip = new MovieClip();
				var name_str:String = "instance" + i;
				_mc.name = name_str;
				_mc.id = i;
				instances[i] = _mc;
				myDictionary[_mc] = i;
				myObject[name_str] = i;
			}
		}
		private function useDynamicVariable():void {
			started = getTimer();
			for (var i:int = 0; i < AMOUNT; i++) {
				var _mc:MovieClip = instances[i];
				var temp:uint = _mc.id;
			}
			xTrace(getTimer() - started);
		}
		private function useObject():void {
			started = getTimer();
			for (var i:int = 0; i < AMOUNT; i++) {
				var _mc:MovieClip = instances[i];
				var temp:uint = myObject[_mc.name];
			}
			xTrace(getTimer() - started);
		}
		private function useDictionary():void {
			started = getTimer();
			for (var i:int = 0; i < AMOUNT; i++) {
				var _mc:MovieClip = instances[i];
				var temp:uint = myDictionary[_mc];
			}
			xTrace(getTimer() - started);
		}
		private function createTextField():void {
			addChild(my_txt);
			addChild(label_txt);
			my_txt.x +=  30;
			my_txt.autoSize = TextFieldAutoSize.RIGHT;
			my_fmt.align = TextFormatAlign.RIGHT;
			my_txt.defaultTextFormat = my_fmt;
			label_txt.autoSize = TextFieldAutoSize.LEFT;
			label_txt.text = "MovieClip's variable:\nObject:\nDictionary:";
		}
		private function xTrace(n:int):void {
			my_txt.appendText(String(n) + "\n");
		}
	}
}