forked from: Setting a computed number to an element of Array

/**
 * Copyright Fumio ( http://wonderfl.net/user/Fumio )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/wP1C
 */

// forked from Fumio's Setting a computed number to an element of Array
package {
	import flash.display.Sprite;
	import flash.utils.getTimer;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import flash.text.TextFormatAlign;
	[SWF(width = "240",height = "180")]
	public class IndexOfElement extends Sprite {
		private const AMOUNT:uint = 10000000;
		private var my_array:Array = [];
		private var my_txt:TextField = new TextField();
		private var label_txt:TextField = new TextField();
		private var my_fmt:TextFormat = new TextFormat();
		public function IndexOfElement() {
			// Creating a TextField for display
			createTextField();
			createArray();
			warmingUp();
			// Starting Test
			base();
			addInBrackets();
			use_as_InBrackets();
			addAndCastInBrackets();
			assignToTypedVariable();
			multiplyInBrackets();
			multiplyAndCastInBrackets();
		}
		private function warmingUp():void {
			var _array:Array = my_array;
			var nAmount:uint = AMOUNT + 1;
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var n:uint = _array[i];
			}
		}
		private function base():void {
			var _array:Array = my_array;
			var nAmount:uint = AMOUNT + 1;
			var started:int = getTimer();
			for (var i:uint = 1; i < nAmount; i++) {
				var n:uint = _array[i];
			}
			xTrace("base ([i])",getTimer() - started);
		}
		private function addInBrackets():void {
			var _array:Array = my_array;
			var nAmount:uint = AMOUNT;
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var n:uint = _array[i + 1];
			}
			xTrace("[i + 1]",getTimer() - started);
		}
		private function use_as_InBrackets():void {
			var _array:Array = my_array;
			var nAmount:uint = AMOUNT;
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var n:uint = _array[(i + 1) as uint];
			}
			xTrace("[(i + 1) as uint]",getTimer() - started);
		}
		private function addAndCastInBrackets():void {
			var _array:Array = my_array;
			var nAmount:uint = AMOUNT;
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var n:uint = _array[uint(i + 1)];
			}
			xTrace("[uint(i + 1)]",getTimer() - started);
		}
		private function assignToTypedVariable():void {
			var _array:Array = my_array;
			var nAmount:uint = AMOUNT;
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var j:uint = i + 1
				var n:uint = _array[j];
			}
			xTrace("var j:uint = i + 1",getTimer() - started);
		}
		private function multiplyInBrackets():void {
			var _array:Array = my_array;
			var nAmount:uint = AMOUNT + 1;
			var started:int = getTimer();
			for (var i:uint = 1; i < nAmount; i++) {
				var n:uint = _array[i * 1.0];
			}
			xTrace("[i * 1.0]",getTimer() - started);
		}
		private function multiplyAndCastInBrackets():void {
			var _array:Array = my_array;
			var nAmount:uint = AMOUNT + 1;
			var started:int = getTimer();
			for (var i:uint = 1; i < nAmount; i++) {
				var n:uint = _array[uint(i * 1.0)];
			}
			xTrace("[uint(i * 1.0)]",getTimer() - started);
		}
		private function createArray():void {
			var nLength:uint = AMOUNT + 1;
			for (var i:uint = 0; i < nLength; i++) {
				my_array[i] = i;
			}
		}
		private function createTextField():void {
			addChild(my_txt);
			addChild(label_txt);
			my_fmt.align = TextFormatAlign.RIGHT;
			my_txt.x += 10;
			my_txt.defaultTextFormat = my_fmt;
			my_txt.autoSize = TextFieldAutoSize.RIGHT;
			label_txt.autoSize = TextFieldAutoSize.LEFT;
		}
		private function xTrace(_str:String,n:int):void {
			my_txt.appendText((String(n) + "\n"));
			label_txt.appendText(((_str + ":") + "\n"));
		}
	}
}