BounceInTheBox

/**
 * Copyright fakestar0826 ( http://wonderfl.net/user/fakestar0826 )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/voJy
 */

package {
    import flash.events.Event;
    import flash.display.Sprite;
    public class FlashTest extends Sprite {
        
        private var balls:Array;
        private var numBalls:int = 50;
        private var fl:Number = 250;
        private var vpX:Number = stage.stageWidth / 2;
        private var vpY:Number = stage.stageHeight / 2;
        private var top:Number = -100;
        private var bottom:Number = 100;
        private var left:Number = -100;
        private var right:Number = 100;
        private var front:Number = 100;
        private var back:Number = -100;
        
        public function FlashTest() {
            // write as3 code here..
            balls = [];
            for(var i:int = 0;i < numBalls;i++)
            {
                var b:Ball3D = new Ball3D(15);
                balls[i] = b;
                b.vx = Math.random() * 10 - 5;
                b.vy = Math.random() * 10 - 5;
                b.vz = Math.random() * 10 - 5;
                addChild(b);
            }
            
            addEventListener(Event.ENTER_FRAME, onEnterFrame);
        }
        
        private function onEnterFrame(e:Event):void
        {
            for(var i:int = 0;i < numBalls;i++)
            {
                var b:Ball3D = balls[i];
                move(b);
            }
        }
        
        private function move(b:Ball3D):void
        {
            var r:Number = b.r;
            
            b.xpos += b.vx;
            b.ypos += b.vy;
            b.zpos += b.vz;
            
            if(b.xpos  + r > right)
            {
                b.xpos = right - r;
                b.vx += -1;
            }
            else if(b.xpos - r < left)
            {
                b.xpos = left + r;
                b.vx *= -1;
            }
            if(b.ypos + r > bottom)
            {
                b.ypos = bottom - r;
                b.vy *= -1;
            }
            else if(b.ypos - r < top)
            {
                b.ypos = top + r;
                b.vy *= -1;
            }
            if(b.zpos + r > front)
            {
                b.zpos = front - r;
                b.vz *= -1;
            }
            else if(b.zpos - r < back)
            {
                b.zpos = back + r;
                b.vz *= -1;
            }
            
            if(b.zpos > -fl)
            {
                var scale:Number = fl / (fl + b.zpos);
                b.scaleX = b.scaleY = scale;
                b.x = vpX + b.xpos * scale;
                b.y = vpY + b.ypos * scale;
                b.visible  = true;
            }
            else
            {
                b.visible = false;
            }







        }

    }
}
import flash.display.Sprite;

class Ball3D extends Sprite
{
    public var r:Number;
    public var xpos:Number = 0;
    public var ypos:Number = 0;
    public var zpos:Number = 0;
    public var vx:Number = 0;
    public var vy:Number = 0;
    public var vz:Number = 0;
    public var mass:Number = 1;
    
    public function Ball3D(r:Number = 40, c:uint = 0xFF0000)
    {
        this.r = r;
        graphics.beginFill(c);
        graphics.drawCircle(0, 0, r);
        graphics.endFill();
    }

}