Chapter 37 Example 8

/**
 * Copyright actionscriptbible ( http://wonderfl.net/user/actionscriptbible )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/uvEg
 */

package {
  import flash.display.Sprite;
  import flash.filters.ColorMatrixFilter;

  public class ch37ex8 extends Sprite {
    function ch37ex8() {
      var original:TestImage = new TestImage(0.5);
      var neg:TestImage = new TestImage(0.5, 250);
      addChild(original);
      addChild(neg);
      var negMatrix:Array = [-1,  0,  0, 0, 255,
                              0, -1,  0, 0, 255,
                              0,  0, -1, 0, 255,
                              0,  0,  0, 1,   0];
      neg.filters = [new ColorMatrixFilter(negMatrix)];
    }
  }
}
import flash.display.Loader;
import flash.net.URLRequest;
import flash.system.LoaderContext;
class TestImage extends Loader {
  public function TestImage(scale:Number = 1, x:Number = 0, y:Number = 0) {
    //photo   (CC-BY) Roger Braunstein
    //source  http://www.flickr.com/photos/rogerimp/2940373537/
    var url:String = "http://actionscriptbible.com/files/heiwadoori.jpg";
    load(new URLRequest(url), new LoaderContext(true));
    scaleX = scaleY = scale;
    this.x = x; this.y = y;
  }
}