10万パーティクルお絵かき

/**
 * Copyright shohei909 ( http://wonderfl.net/user/shohei909 )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/tj9k
 */

// forked from shohei909's forked from: 重力マウス（100万パーティクル）
// forked from clockmaker's 重力マウス（100万パーティクル）
// forked from cjcat2266's 重力マウス（プチ軽量化：25万パーティクル）
// forked from clockmaker's 重力マウス（プチ軽量化：10万パーティクル）
// forked from coppieee's 重力マウス（さらに軽量化してみた）
// forked from paq's forked from: 重力マウス（ちょっぴり軽量化してみた）
// forked from fumix's 重力マウス（リンクリストにしてみた）
// forked from undo's 重力マウス
//　リンクリストにしてみたけどそんなに速くない？？
//_bmd.fillRect()を_bmd.setPixel()に変更。
//sin(),cos(),atan2(),sqrt()を排除。
// Add final class / mouseEnalbled = false by clockmaker
// CJ Cat: Used vector instead of linked list.
// clockmaker: while文の処理を4回コピペしてイテレーションの回数を減らす 100万で30fps (FP10.1 Release))
package
{
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.geom.ColorTransform;
    import flash.geom.Rectangle;
    import net.hires.debug.Stats;

    [SWF(frameRate='120', width='465', height='465', backgroundColor='0x0')]

    public class Main extends Sprite {
        private const _bmd:BitmapData = new BitmapData(465, 465, false, 0x000000);
        private const _bmp:Bitmap = new Bitmap(_bmd);
        private const _bmdRect:Rectangle = _bmd.rect;
        private var _colorTransform:ColorTransform = new ColorTransform(0.9995, 0.995, 0.95, 1.0);

        private const _maxNum:int = 100000;
        private var _cnt:int = 0;
        
        private const _particleData1:Vector.<Number> = new Vector.<Number>(_maxNum, true);
        private const _particleData2:Vector.<Number> = new Vector.<Number>(_maxNum, true);
        private const _particleData3:Vector.<Number> = new Vector.<Number>(_maxNum, true);
        private const _particleData4:Vector.<Number> = new Vector.<Number>(_maxNum, true);
        

        public function Main() {
            this.stage.align = "topLeft";
            this.stage.scaleMode = "noScale";
            this.stage.quality = "low";
            this.mouseEnabled = false;
            this.mouseChildren = false;
        
            addChild(_bmp);
            
            var i:uint = 0;
            do{
                _particleData1[i] = Math.random() * 465 >> 0;
                _particleData2[i] = Math.random() * 465 >> 0;
                _particleData3[i] = 0;
                _particleData4[i] = 0;
            }while (++i < _maxNum ) 
            
            addChild(new Stats());
            addEventListener("exitFrame", frame);
        }

        private function frame(evt:Event):void {
            var i:uint = 0, p1:int, p2:int;
            const gravPoint_x:int = mouseX, gravPoint_y:int = mouseY, calc:Boolean = _cnt == 0;
            this._bmd.lock();
            var vec:Vector.<uint> = this._bmd.getVector(this._bmdRect);
            
            if(calc){
                var diff_x:int, diff_y:int, acc:Number, p3:Number, p4:Number;
                do
                {   
                    diff_x = gravPoint_x - (p1 = _particleData1[i] += p3 = _particleData3[i])
                    diff_y = gravPoint_y - (p2 = _particleData2[i] += p4 = _particleData4[i])
                    acc = 0x100 / (diff_x * diff_x + diff_y * diff_y + 4)
                    _particleData3[i] = ( p3 + acc * diff_x ) * 0.84
                    _particleData4[i] = ( p4 + acc * diff_y ) * 0.84
                    if( 0 < p1 && p1 < 465 && 0 < p2 && p2 < 465 ){ vec[p1 + p2 * 465] += 0x20408  }
                }while(++i < _maxNum)
            }else{
                do
                {   
                    p1 = _particleData1[i] += _particleData3[i];
                    p2 = _particleData2[i] += _particleData4[i];
                    if( 0 < p1 && p1 < 465 && 0 < p2 && p2 < 465 ){ vec[p1 + p2 * 465] += 0x20408 }
                }while(++i < _maxNum)
            }
            this._bmd.setVector(this._bmdRect, vec);
            this._bmd.colorTransform(this._bmdRect, this._colorTransform);
            this._bmd.unlock();
            
            _cnt++;
            if(_cnt == 10 ){ _cnt = 0 }
        }
    }
}