Project Euler 116

/**
 * Copyright uwi ( http://wonderfl.net/user/uwi )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/tYNk
 */

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.utils.getTimer;
    // @see http://projecteuler.net/index.php?section=problems&id=116
    public class Euler116 extends Sprite {
        private var _tf : TextField;
  
        public function Euler116() {
            _tf = new TextField();
            _tf.width = 465;
            _tf.height = 465;
            addChild(_tf);
            
            var s : int = getTimer();
            _tf.appendText(solve().toString() + "\n");
            var g : int = getTimer();
            _tf.appendText((g - s).toString() + " ms\n");
        }
        
        private var _cache : Array;
        private const N : int = 50;
        
        private function solve() : Number
        {
            _cache = [];
            var sum : Number = 0;
            var i : int = 0;
            
            for(i = 0;i <= N;i++)_cache[i] = -1;
            _cache[0] = 1;
            sum += nReplace(N, [1, 2]) - 1;
            for(i = 0;i <= N;i++)_cache[i] = -1;
            _cache[0] = 1;
            sum += nReplace(N, [1, 3]) - 1;
            for(i = 0;i <= N;i++)_cache[i] = -1;
            _cache[0] = 1;
            sum += nReplace(N, [1, 4]) - 1;
            return sum;
        }
        
        private function nReplace(n : int, lens : Array) : Number
        {
            if(_cache[n] != -1)return _cache[n];
            
            var sum : Number = 0;
            for each(var len : int in lens){
                if(n >= len){
                    sum += nReplace(n - len, lens);
                }
            }
            _cache[n] = sum;
            return sum;
        }
    }
}