画面スクロールB

/**
 * Copyright tepe ( http://wonderfl.net/user/tepe )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/saJX
 */

package {
    import flash.display.Sprite;
    public class FlashTest extends Sprite {
        private var sc:overScroll = new overScroll();
        private var s:Sprite = new Sprite();
        public function FlashTest() {
            // write as3 code here..
            s.graphics.beginFill(0x000000);
            s.graphics.drawRect(0,0,50,50);
            s.graphics.endFill();
            s.x = 100;
            s.y = 100;
            addChild(s);
            sc.showArea=true;
            sc.setArea(223,223,150);
            sc.movSpeed=0.1;
            sc.setTarget(s);
            addChild(sc);
        }
    }
}

    import flash.geom.*;
    import flash.display.*;
    import flash.events.*;
    class overScroll extends Sprite{
        //private var s:Sprite = new Sprite();
        private var target:DisplayObject;
        private var r:Number;
        public var movSpeed:Number = 0.01;
        public var showArea:Boolean = false;
        private var move:Point = new Point();
        public function overScroll(){
            
             
            addEventListener(MouseEvent.MOUSE_OVER,overMouse);
            addEventListener(MouseEvent.MOUSE_OUT,outMouse);
            
            
        }
        public function setTarget(t:DisplayObject=null):void{
            if(t==null){
                removeEventListener(Event.ENTER_FRAME,onEnter);
                removeEventListener(MouseEvent.MOUSE_OVER,overMouse);
                removeEventListener(MouseEvent.MOUSE_OUT,outMouse);
            }
            target = t;

        }

        public function setArea(x:Number,y:Number,r:Number):void{
            this.x = x;
            this.y = y;
            this.r = r;
            graphics.clear();
            if(showArea==false)graphics.beginFill(0x000000,0);
            else graphics.beginFill(0xff0000,0.5);
            graphics.drawCircle(0,0,r);
            graphics.endFill();
        }

        
        private function overMouse(e:MouseEvent):void{
            stage.removeEventListener(Event.MOUSE_LEAVE,leave);
            removeEventListener(Event.ENTER_FRAME,slowDown);
            removeEventListener(Event.ENTER_FRAME,onEnter);
            //state = "overMouse";
        }
        private function outMouse(e:MouseEvent):void{
            stage.addEventListener(Event.MOUSE_LEAVE,leave);
            addEventListener(Event.ENTER_FRAME,onEnter);
            //state = "outMouse";
        }
        private function leave(e:Event):void{
            removeEventListener(Event.ENTER_FRAME,onEnter);
            addEventListener(Event.ENTER_FRAME,slowDown);
            //state = "mouseLeave";
        }
        
        public function scrOn():void{
            addEventListener(MouseEvent.MOUSE_OVER,overMouse);
            addEventListener(MouseEvent.MOUSE_OUT,outMouse);
        }
        public function scrOff():void{
            removeEventListener(Event.ENTER_FRAME,onEnter);
            removeEventListener(MouseEvent.MOUSE_OVER,overMouse);
            removeEventListener(MouseEvent.MOUSE_OUT,outMouse);
        }
        private function slowDown(e:Event):void{
            target.x -=move.x*movSpeed; target.y -=move.y*movSpeed;
            move.x /= 1.02;move.y /= 1.02;
            if(Math.abs(move.x)<0.1 && Math.abs(move.y)<0.1) removeEventListener(Event.ENTER_FRAME,slowDown);
        }
        
        private function onEnter(e:Event):void{
            var mp:Point = new Point(mouseX,mouseY);
            var p:Point = new Point(0,0);
            var n:Number = Point.distance(p, mp);//中心からの距離
            var v:Point = mp.subtract(p);
            //v=(x=290,y=380)
            var angle:Number = Math.atan2(v.y,v.x);            
            
            if(r<n){//エリア外   
                move = Point.polar(n-r,angle);
                target.x -=move.x*movSpeed; target.y -=move.y*movSpeed;
            }
            
        }
    }