forked from: エディタ　サンプル

/**
 * Copyright tepe ( http://wonderfl.net/user/tepe )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/sI2p
 */

package {
    import flash.display.*;
    import flash.text.*;
    public class FlashTest extends Sprite {
        public var t1:TextEditor = new TextEditor();
        public function FlashTest() {
            
            addChild(t1);
            t1.x = 150;
            t1.y = 100;
            t1.border = true;
            
            var te:TextEditor = new TextEditor();
            addChild(te);
            var te2:TextEditor = new TextEditor();
            addChild(te2);
            te2.x = 150;
            te2.border = true;
            te.border = true;
            te.next = te2;
            
            var t3:TextEditor = new TextEditor();
            addChild(t3);
            t3.border = true;
            te2.next = t3;//t3.prev = te2;
            t3.x = 300;
            
            var t4:TextEditor = new TextEditor();
            addChild(t4);
            t4.border = true;
            t3.next = t4;//t3.prev = te2;
            t4.y = 100;
            //te2.prev= te;
            //te.selectable = false;
            //te.text = te.fontSize.toString();
            //te.fontSize = 30;
        }
        
    }
}


////////////////////////////////////////////////////////////////////////
//  TextEditor class
////////////////////////////////////////////////////////////////////////

/*
    --TextFieldへの追加機能--
        ・改行入力
        ・タブ入力
        ・オートインデント
        ・アンドゥ/リドゥ
*/
    import flash.desktop.Clipboard;
    import flash.ui.Keyboard;
    import flash.text.*;
    import flash.events.*;
    class TextEditor extends TextField {
        
        private var _prev:TextEditor;
        private var _next:TextEditor;
        
        public var autoResize:Boolean = true;//文章に合わせて自動リサイズ
        private var prevText:String = "";//text変更前の状態
        private var indentStr:String;
        private var sc:StringComparator = new StringComparator();
        private var historyManager:HistoryManager = new HistoryManager();
        private var comparator:StringComparator = new StringComparator();
        private static var textFormat:TextFormat = new TextFormat();
        
        public function TextEditor():void {
            this.type = "input";//入力可能
            //this.multiline = true;//マルチライン
            this.addEventListener(KeyboardEvent.KEY_DOWN, onKey); 
            
            this.addEventListener(FocusEvent.KEY_FOCUS_CHANGE,function(e:FocusEvent):void{
                e.preventDefault();//タブキーによるフォーカス変更をキャンセル
            });

            this.addEventListener(Event.CHANGE,onChange);//textの変更
            this.defaultTextFormat = textFormat;
            this.addEventListener(KeyboardEvent.KEY_UP,offKey);
            textFormat = new TextFormat();
            this.defaultTextFormat = textFormat;
            onChange(null);

        }
        private function offKey(e:KeyboardEvent):void{
            onChange(null);
            this.removeEventListener(Event.ENTER_FRAME,onFrame);
        }
        
        private function onFrame(e:Event):void{
            onChange(null);
        }

        
        private var sw:Boolean;
        private function onChange(e:Event=null):void{  
            
            //リサイズ
            if(autoResize==true){
                resize();
                if(width<50)width=50;
            }

            //undo redo
            if(sw==false)addHistory();//アンドゥ、リドゥの操作では登録しない
            else{
                prevText = this.text;
                sw=false;      
            }
            
            
            if(sw2==true){//コピー＆ペーストの対応
                this.multiline = false;
                sw2=false;
            }

        }
        
        public function resize():void{
            width = textWidth+5;
            height = textHeight+5;
            scrollH = 0;
            scrollV = 0;
        }

        
        //フォント名
        public function set font(fontName:String):void{
            textFormat.font = fontName;
            this.defaultTextFormat = textFormat;
            onChange();
        }
        public function get font():String{
            return textFormat.font;
        }

        //フォントサイズ        
        public function set fontSize(size:Object):void{
            textFormat.size = size;
            this.defaultTextFormat = textFormat;
            onChange();
        }
        public function get fontSize():Object{
            return textFormat.size; 
        }
        
        //前のエディタ領域
        public function set prev(t:TextEditor):void{
            _prev = t;
            if(_prev.next != this)_prev.next = this;
        }
        public function get prev():TextEditor{
            return _prev;
        }
        
        //次のエディタ領域
        public function set next(t:TextEditor):void{
            _next = t;
            if(_next.prev != this)_next.prev = this;
        }
        public function get next():TextEditor{
            return _next;
        }

        //キャレットの位置設定
        public function set caret(index:int):void{
            this.setSelection(index,index);
            stage.focus = this;
        }
        public function get caret():int{
            return this.caretIndex;
        }





        
        //入力履歴更新
        private function addHistory():void{
            if(prevText==this.text)return;
            comparator.compare(prevText, this.text);   
            var entry:HistoryEntry = new HistoryEntry(comparator.commonPrefixLength);      
                entry.removeText = prevText.substring(comparator.commonPrefixLength, prevText.length - comparator.commonSuffixLength);
                entry.addText = this.text.substring(comparator.commonPrefixLength, this.text.length - comparator.commonSuffixLength);
                historyManager.appendEntry(entry); 
                prevText = this.text;
        }

        
        //キー入力
        private var sw2:Boolean;
        private function onKey(e:KeyboardEvent):void {       
            this.addEventListener(Event.ENTER_FRAME,onFrame); 
            // Ctrl+Z : UNDO
            if (e.keyCode == 90 && e.ctrlKey) {
                sw=true;
                undo();
                return;
            }
        
            // Ctrl+Y : REDO
            if (e.keyCode == 89 && e.ctrlKey) {
                sw=true;
                redo();
                return;
            }
            //ペースト
            if(e.keyCode == 86 && e.ctrlKey){
                this.multiline = true;//改行を含むコピーに対応
                sw2=true;
            }

            
            //キャレット位置に改行文字を挿入
            if(e.keyCode == 13 || e.keyCode == 108){
                lineFeed();
                return;
            }
            //tab
            if (e.keyCode == 9) {
                tab();
                return;
            }
            
            //キャレットの移動
            if(this.caretIndex==0 && _prev!=null){
                if(e.keyCode == 37 || e.keyCode == 38){
                    //e.stopPropagation();
                    
                    _prev.caret = _prev.length;
                    return;
                }
            }
            if(this.caretIndex==this.length && _next!=null){
                if(e.keyCode==39 || e.keyCode==40){
                    _next.caret = 0;
                    return;
                }
            }
        }
        

        
        //改行
        
        public function lineFeed():void{
            //sw2=true;
            var str1:String;
            var str2:String;
            var scrV:int = this.scrollV;
            str1 = this.text.substring(0, this.caretIndex);
            str2 = this.text.substring(this.caretIndex, this.length);
            this.text = str1;
            this.appendText("\n");//キャレット位置で改行
                
            //インデント構造（タブ＆スペースの構成）を調べる
            var indent:int=0;
            var prevReturn:int = this.text.lastIndexOf('\r', this.caretIndex-1);//前回の改行位置
            //一つ前の改行直後に続くタブコードの数=インデント深度
            for (var j:int = prevReturn+1; j < this.caretIndex; j++) {
                if (this.text.charAt(j) == '\t' || this.text.charAt(j) == ' ' ) indent++;
                else break;
            }
            //上の行のインデントに従う
            var iStr:String = this.text.slice(prevReturn + 1, prevReturn + 1 + indent);
            indentStr = iStr;
            this.appendText(iStr);//インデント
            this.text += str2;//結合 
             
            //キャレット位置をインクリメント
            this.scrollV = scrV;
            this.setSelection(this.caretIndex +indent + 1, this.caretIndex +indent + 1);
            
            this.dispatchEvent(new Event(Event.CHANGE));
            
        }

        //タブ
        public function tab():void{
            var str1:String;
            var str2:String;
            str1 = this.text.substring(0, this.caretIndex);
            str2 = this.text.substring(this.caretIndex, this.length);
            this.text = str1 + '\t' + str2;
            //キャレット位置をインクリメント
            this.setSelection(this.caretIndex + 1, this.caretIndex + 1);        
            this.dispatchEvent(new Event(Event.CHANGE));
        }

        //アンドゥ
        public function undo():void {
            if (historyManager.canBack) {
                var entry:HistoryEntry = historyManager.back();
                //テキストセット
                this.replaceText(entry.index, entry.index + entry.addText.length, entry.removeText);
                //キャレット位置セット
                this.setSelection(entry.index + entry.removeText.length, entry.index + entry.removeText.length);               
            }
            this.dispatchEvent(new Event(Event.CHANGE));           
        }
    
        //リドゥ
        public function redo():void {
            if (historyManager.canForward) {
                var entry:HistoryEntry = historyManager.forward();
                //テキストセット
                this.replaceText(entry.index, entry.index + entry.removeText.length, entry.addText);
                //キャレット位置セット
                this.setSelection(entry.index + entry.addText.length, entry.index + entry.addText.length);            
            }
            this.dispatchEvent(new Event(Event.CHANGE));         
        }
        
    }


import __AS3__.vec.Vector;

class HistoryManager {
    public var currentIndex:int = 0;
    public var length:int=0;
    private var entries:Vector.<HistoryEntry>;
    
    public function HistoryManager() {
        entries = new Vector.<HistoryEntry>();
    }
    //履歴追記
    public function appendEntry(entry:HistoryEntry):void {
        entries.length = currentIndex;
        length = entries.length;
        entries.push(entry);
        currentIndex++;// = entries.length;
    }
    //履歴削除
    public function clear():void {
        currentIndex = 0;
        entries.length = 0;
    }
    //リドゥ可能
    public function get canForward():Boolean {
        return currentIndex < entries.length;
    }
    //アンドゥ可能
    public function get canBack():Boolean {
        return currentIndex > 0;
    }
    //リドゥ
    public function forward():HistoryEntry {
        return entries[currentIndex++];
    }
    //アンドゥ
    public function back():HistoryEntry {
        return entries[--currentIndex];
    }

}


class HistoryEntry {
    public var index:int;//文字列の位置
    public var removeText:String;
    public var addText:String;
    
    public function HistoryEntry(index:int=0, remove:String="", add:String="") {
        this.index   = index;//文字列先頭位置
        this.removeText = remove;//消した文字列
        this.addText = add;//追加した文字列
    }
}
    

 // 文字列の左右一致を数える
class StringComparator {
    // 左側の共通文字列長
    public var commonPrefixLength:int;    
    // 右側の共通文字列長
    public var commonSuffixLength:int;
    /**
     * 2つの文字列を比較し、commonPrefixLengthとcommonSuffixLengthをセットする
     * 
     * @param str1 比較する文字列の一方
     * @param str2 比較する文字列の他方
     */
    public function compare(str1:String, str2:String):void {
        var minLength:int = Math.min(str1.length, str2.length);
        var step:int, l:int, r:int;
        
        step = Math.pow(2, Math.floor(Math.log(minLength) / Math.log(2)));
        for (l=0; l<minLength; ) {
            if (str1.substr(0, l + step) != str2.substr(0, l + step)) {
                if (step == 1) { break; }
                step >>= 1;
            } else {
                l += step;
            }
        }
        l = Math.min(l, minLength);
        
        minLength -= l;
        
        step = Math.pow(2, Math.floor(Math.log(minLength) / Math.log(2)));
        for (r=0; r<minLength; ) {
            if (str1.substr(-r - step) != str2.substr(-r - step)) {
                if (step == 1) { break; }
                step >>= 1;
            } else {
                r += step;
            }
        }
        r = Math.min(r, minLength);
        
        commonPrefixLength = l;
        commonSuffixLength = r;
    }    
}