Getting distance with Point.distance() and Math.sqrt() methods

/**
 * Copyright Fumio ( http://wonderfl.net/user/Fumio )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/rUa2
 */

package {
	import flash.display.Sprite;
	import flash.utils.getTimer;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import flash.text.TextFormatAlign;
	import flash.geom.Point;
	[SWF(width = "240",height = "180")]
	public class GettingDistance extends Sprite {
		private const AMOUNT:uint = 1000000;
		private var myVector:Vector.<Point> = new Vector.<Point>(AMOUNT);
		private var my_txt:TextField = new TextField();
		private var label_txt:TextField = new TextField();
		private var my_fmt:TextFormat = new TextFormat();
		public function GettingDistance() {
			// Creating a TextField for display
			createTextField();
			createPoints();
			// Starting Test
			test(warmingUp, "empty loop");
			test(useMath, "Math.sqrt()");
			test(usePoint, "Point.distance()");
		}
		private function test(myFunction:Function,label_str:String):void {
			var _vector:Vector.<Point>  = myVector;
			var nAmount:uint = _vector.length - 1;
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var beginPoint:Point = _vector[i];
				var endPoint:Point = _vector[uint(i + 1)];
				var distance:Number = myFunction(beginPoint, endPoint);
			}
			xTrace(label_str,getTimer() - started);
		}
		private function usePoint(beginPoint:Point, endPoint:Point):Number {
			var distance:Number = Point.distance(beginPoint, endPoint);
			return distance;
		}
		private function useMath(beginPoint:Point, endPoint:Point):Number {
			var nX:Number = endPoint.x - beginPoint.x;
			var nY:Number = endPoint.y - beginPoint.y;
			var distance:Number = Math.sqrt(nX * nX + nY * nY);
			return distance;
		}
		private function warmingUp(beginPoint:Point, endPoint:Point):Number {
			return 0;
		}
        private function createPoints():void {
            var nAmount:uint = AMOUNT;
            for (var i:uint = 0; i < nAmount; i++) {
				var nX:Number = Math.random() * 1000;
				var nY:Number = Math.random() * 1000;
                myVector[i] = new Point(nX, nY);
            }
        }
        private function createTextField():void {
            addChild(my_txt);
            addChild(label_txt);
            my_fmt.align = TextFormatAlign.RIGHT;
            my_txt.x +=  50;
            my_txt.defaultTextFormat = my_fmt;
            my_txt.autoSize = TextFieldAutoSize.RIGHT;
            label_txt.autoSize = TextFieldAutoSize.LEFT;
        }
        private function xTrace(_str:String, n:int):void {
            my_txt.appendText(String(n) + "\n");
            label_txt.appendText(_str + ":" + "\n");
        }
	}
}