ゆらゆらパンダ

/**
 * Copyright ProjectNya ( http://wonderfl.net/user/ProjectNya )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/qR2g
 */

////////////////////////////////////////////////////////////////////////////////
// ゆらゆらパンダ
////////////////////////////////////////////////////////////////////////////////

package {

    import flash.display.Sprite;
    import flash.display.MovieClip;
    import flash.display.Loader;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.net.URLRequest;
    import flash.system.Security;
    import flash.system.LoaderContext;
    import flash.display.Shape;
    import flash.geom.Matrix;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.InterpolationMethod;
    import frocessing.color.ColorHSV;

    [SWF(backgroundColor="#FFFFFF", width="465", height="465", frameRate="30")]

    public class Main extends Sprite {
        private static var basePath:String = "http://assets.wonderfl.net/images/related_images/";
        private static var sunshinePath:String = "9/9b/9bbe/9bbec77d53bddc5e7a5f2c00abbade6bd641c549";
        private var loader:Loader;
        private static var pandaPath:String = "http://www.project-nya.jp/images/flash/panda2d.swf";
        private var Panda:Class;
        private var panda:MovieClip;
        private var velocity:Number = 0;
        private var angle:Number = 0;
        private static var radius:uint = 15;
        private static var radian:Number = Math.PI/180;

        public function Main() {
            //Wonderfl.disable_capture();
            //Wonderfl.capture_delay(4);
            init();
        }

        private function init():void {
            draw();
            Security.allowDomain("www.project-nya.jp");
            loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, complete, false, 0, true);
            loader.load(new URLRequest(pandaPath), new LoaderContext(true));
        }
        private function complete(evt:Event):void {
            loader.removeEventListener(Event.COMPLETE, complete);
            var content:MovieClip = MovieClip(evt.target.content);
            //Pandaクラス
            Panda = MovieClip(content.panda).constructor;
            setup();
            loader = null;
        }
        private function setup():void {
            //Pandaインスタンス
            panda = new Panda();
            addChild(panda);
            panda.x = 232;
            panda.y = 350;
            panda.scale = 2.5;
            //panda.shade.visible = false;
            panda.handL.stop();
            panda.handR.stop();
            panda.handL.gotoAndPlay(19);
            panda.handR.gotoAndPlay(1);
            addEventListener(Event.ENTER_FRAME, update, false, 0, true);
        }
        private function update(evt:Event):void {
            angle += 3;
            velocity = radius*Math.sin(angle*radian);
            panda.base.rotation = velocity;
        }
        /////////////////////////////////////////////
        //背景
        /////////////////////////////////////////////
        private function draw():void {
            drawSky();
            drawGround();
            drawSun();
            drawBox();
        }
        private function drawSky():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(465, 350, 0.5*Math.PI, 0, 0);
            graphics.beginGradientFill(GradientType.LINEAR, [0x3F68AB, 0x77B2EE], [1, 1], [0, 255], matrix);
            graphics.drawRect(0, 0, 465, 350);
            graphics.endFill();
        }
        private function drawGround():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(465, 115, 0.5*Math.PI, 0, 350);
            graphics.beginGradientFill(GradientType.LINEAR, [0x99CC33, 0x7EB133], [1, 1], [0, 255], matrix);
            graphics.drawRect(0, 350, 465, 115);
            graphics.endFill();
        }
        private function drawSun():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(200, 200, 0, -90, -90);
            graphics.beginGradientFill(GradientType.RADIAL, [0xFFFFFF, 0xFFFFFF, 0xFFFFFF], [1, 0.3, 0], [25, 102, 231], matrix);
            graphics.drawCircle(10, 10, 100);
            graphics.endFill();
            var shine:Loader = new Loader();
            addChild(shine);
            shine.alpha = 0.5;
            shine.load(new URLRequest(basePath + sunshinePath), new LoaderContext(true));
        }
        private function drawBox():void {
            var _width:uint = 140;
            var _height:uint = 60;
            var box:Sprite = new Sprite();
            addChild(box);
            box.x = 232;
            box.y = 430;
            var top:Shape = new Shape();
            box.addChild(top);
            top.graphics.beginFill(0xFFFFFF);
            top.graphics.moveTo(-_width*0.5, -_height);
            top.graphics.lineTo(-_width*0.36, -_height-_width*0.24);
            top.graphics.lineTo(_width*0.36, -_height-_width*0.24);
            top.graphics.lineTo(_width*0.5, -_height);
            top.graphics.endFill();
            var light:ColorHSV = new ColorHSV();
            light.value = 0xFF0000;
            light.v = 1.2;
            var dark:ColorHSV = new ColorHSV();
            dark.value = 0xFF0000;
            dark.v = 0.4;
            var front:Shape = new Shape();
            box.addChild(front);
            var colors:Array = [light.value, dark.value];
            var alphas:Array = [1, 1];
            var ratios:Array = [0, 255];
            var matrix:Matrix = new Matrix();
            var offset:Number = _width*0.05;
            matrix.createGradientBox(_width*2, _width*2, 0, -_width*1.5+offset, -_height-_width+offset);
            front.graphics.beginGradientFill(GradientType.RADIAL, colors, alphas, ratios, matrix, SpreadMethod.PAD, InterpolationMethod.RGB, 0);
            front.graphics.drawRect(-_width*0.5, -_height, _width, _height);
            front.graphics.endFill();
        }

    }

}