[最適化 Tips] Dictionaryのキーの型による処理の速度比較

/**
 * Copyright NOB_Q ( http://wonderfl.net/user/NOB_Q )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/miIc
 */

// forked from muta244's [最適化 Tips] 各オブジェクトの型変換に掛かる処理の速度比較
// 検証方法なんか間違っているかも・・・
package {

import flash.display.*;
import flash.geom.*;
import flash.events.*;
import flash.text.*;
import flash.utils.*;

public class Main extends Sprite
{
    static private const _NUM_TIMES:int = 500000;
    
    private function _init():void
    {
        _debug(
            "各テスト " + _NUM_TIMES + " 回処理させた計算結果 [単位 ： ミリ秒]\n" +
            "(誤差は多少生じます)\n"
        );
        
        var intKey:Vector.<int> = new Vector.<int>(_NUM_TIMES);
        var intDictionary:Dictionary = new Dictionary();
        for (var i:int = 0; i < _NUM_TIMES; i++) {
            intKey[i] = i;
            intDictionary[intKey[i]] = i;
        }
        
        var strKey:Vector.<String> = new Vector.<String>(_NUM_TIMES);
        var strDictionary:Dictionary = new Dictionary();
        for (i = 0; i < _NUM_TIMES; i++) {
            strKey[i] = i.toString();
            strDictionary[intKey[i]] = i;
        }
        
        _measure("ループのみ", function ():void
        {
            for (var i:uint = 0; i < _NUM_TIMES; i++) {
                
            }
        });
        
        _measure("vector.<int> の参照", function ():void
        {
            for (var i:uint = 0; i < _NUM_TIMES; i++) {
                intKey[i];
            }
        });
        
        _measure("vector.<String> の参照", function ():void
        {
            for (var i:uint = 0; i < _NUM_TIMES; i++) {
                strKey[i];
            }
        });
        
        _measure("int をキーにして参照", function ():void
        {
            for (var i:uint = 0; i < _NUM_TIMES; i++) {
                intDictionary[intKey[i]];
            }
        });
        
        _measure("String をキーにして参照", function ():void
        {
            for (var i:uint = 0; i < _NUM_TIMES; i++) {
                strDictionary[strKey[i]];
            }
        });
        
        _debug("\n結果については言及しませんので, 各自ご判断ください.");
    }
    
    private var _field:TextField;
    private var _time:uint;
    
    public function Main():void
    {
        _setup();
        _init();
    }
    
    private function _measure(title:String, func:Function, ...params):void
    {
        _time = getTimer();
        func.apply(null, params);
        _time = getTimer() - _time;
        
        _debug("[ " + title + " ] --> " + _time + " ms");
    }
    
    private function _debug(log:String):void
    {
        _field.appendText(log + "\n");
    }
    
    private function _setup():void
    {
        _field = new TextField();
        _field.width = stage.stageWidth - 40;
        _field.height = stage.stageHeight - 60;
        _field.x = 20;
        _field.y = 60;
        _field.multiline = true;
        _field.wordWrap = true;
        
        var format:TextFormat = _field.defaultTextFormat;
        format.font = "_sans";
        _field.defaultTextFormat = format;
        
        addChild(_field);
        
        var button:Sprite = new Sprite();
        button.graphics.lineStyle(1, 0xBBBBBB);
        button.graphics.beginFill(0xEEEEEE);
        button.graphics.drawRoundRect(0, 0, 100, 20, 5, 5);
        button.graphics.endFill();
        
        addChild(button);
        
        button.x = 20;
        button.y = 20;
        button.mouseChildren = false;
        button.buttonMode = true;
        
        var field:TextField = new TextField();
        field.width = 100;
        field.height = 20;
        field.htmlText = "<p align='center'><font face='_sans'>再計算</span></p>";
        
        button.addChild(field);
        
        button.addEventListener(MouseEvent.CLICK, function ():void
        {
            _field.text = "";
            _init();
        });
    }
}

}