forked from: flash on 2009-11-17

/**
 * Copyright littlepad ( http://wonderfl.net/user/littlepad )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/m3Ox
 */

// forked from littlepad's flash on 2009-11-17
package {
    import flash.display.Sprite;
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.events.Event;
    import flash.filters.BlurFilter;
    import flash.geom.Rectangle;
    import flash.geom.Point;
    import flash.display.BlendMode;
    import flash.geom.ColorTransform;
    import flash.display.PixelSnapping;
    import flash.geom.Matrix;
    import flash.events.TimerEvent;
    import flash.utils.Timer; 
    import flash.events.MouseEvent;
    
    [SWF(width = "465", height = "465", backgroundColor = "0x000000", frameRate = "30")]
    
    public class ParticleTest extends Sprite {
        
        private const WIDTH:Number = 465;        // ステージの横サイズ
        private const HEIGHT:Number = 465;    // ステージの縦サイズ
        private var _canvas:BitmapData;        // キャンバス
        private var _rect:Rectangle;            // 
        private var _cTra:ColorTransform;        //    
        private var _particles:Array;            // パーティクル情報配列
        
        public function ParticleTest() {
            init();
        }
        
        private function init():void {
            _canvas = new BitmapData(WIDTH, HEIGHT, true, 0xFF000000);
            addChild(new Bitmap(_canvas));
            
            _particles = new Array();
            _rect = new Rectangle(0, 0, WIDTH, HEIGHT);
            _cTra = new ColorTransform(.8, .8, .9, 1);
            
            stage.addEventListener(Event.ENTER_FRAME, onEnterFrame);
            
            var timer:Timer = new Timer(1000);
            timer.addEventListener(TimerEvent.TIMER, onTimer);     
            timer.start();  
        }
        
        private function onTimer(e:TimerEvent):void {
                // 一度に描画されるパーティクルの数
            var n:uint = 500;
            
              var rx:uint = Math.random() * 465;
            var ry:uint = Math.random() * 465;
            
            while(n--) {
                var p:Particle = new Particle();
                p.x = rx;
                p.y = ry
                
                var radius:Number = Math.random() * 10;
                var angle:Number = Math.random() * Math.PI*2;
                p.vx = Math.cos(angle) * radius;
                p.vy = Math.sin(angle) * radius;
                
                _particles.push(p);
            }
        }            
        
        private function onEnterFrame(e:Event):void {
                // パフォーマンスを向上させるため、
                // BitmapData をロックして変更を反映させないようにする
            _canvas.lock();
            
            for(var i:uint = 0; i<_particles.length; i++){
                var p:Particle = _particles[i];
                p.vy += 0.2;
                p.vx *= 0.9;
                p.vy *= 0.9;
                p.x += p.vx;
                p.y += p.vy;
                _canvas.setPixel32(p.x, p.y, p.c);
                
                // ステージ外に出たパーティクルを配列から取り除く
                if ((p.x > stage.stageWidth || p.x < 0) || (p.y < 0 || p.y > stage.stageHeight) || Math.abs(p.vx) < .01 || Math.abs(p.vy) < .01)
                {
                    _particles.splice(i, 1);
                }
            }
            // ブラーフィルター
            _canvas.applyFilter(_canvas, _rect, new Point(), new BlurFilter(1,1));
            
            // カラー変換
            _canvas.colorTransform(_rect, _cTra);
            
            // BitmapData のロックを解除し、変更を反映する
            _canvas.unlock();
        }
    }
}
internal class Particle {
    public var x:Number;
    public var y:Number;
    public var vx:Number;
    public var vy:Number;
    public var c:uint;
    
    public function Particle() {
        x = 0;
        y = 0;
        vx = 0;
        vy = 0;
        c = 0xFFFFFFFF;
    }
}