光のなかのひよこちゃん

/**
 * Copyright ProjectNya ( http://wonderfl.net/user/ProjectNya )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/lmnG
 */

////////////////////////////////////////////////////////////////////////////////
// 光のなかのひよこちゃん
////////////////////////////////////////////////////////////////////////////////

package {

    import flash.display.Sprite;
    import flash.display.MovieClip;
    import flash.display.Loader;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.net.URLRequest;
    import flash.system.Security;
    import flash.system.LoaderContext;
    import flash.geom.Matrix;
    import flash.display.GradientType;
    import flash.display.BitmapData;
    import flash.display.Bitmap;
    import flash.display.BlendMode;

    [SWF(backgroundColor="#FFFFFF", width="465", height="465", frameRate="30")]

    public class Main extends Sprite {
        private static var basePath:String = "http://assets.wonderfl.net/images/related_images/";
        private static var sunshinePath:String = "9/9b/9bbe/9bbec77d53bddc5e7a5f2c00abbade6bd641c549";
        private static var lightPath:String = "4/40/400b/400b814a16b90c750e41bcd00890213280cd1be7";
        private var loader:Loader;
        private static var piyoPath:String = "http://www.project-nya.jp/images/flash/piyo2d.swf";
        private var Piyo:Class;
        private var piyo:MovieClip;
        private static var max:uint = 20;
        private var lights:Array;
        private var bitmapData:BitmapData;

        public function Main() {
            //Wonderfl.disable_capture();
            Wonderfl.capture_delay(4);
            init();
        }

        private function init():void {
            draw();
            Security.allowDomain("www.project-nya.jp");
            loader = new Loader();
            loader.contentLoaderInfo.addEventListener(Event.COMPLETE, complete, false, 0, true);
            loader.load(new URLRequest(piyoPath), new LoaderContext(true));
        }
        private function complete(evt:Event):void {
            loader.removeEventListener(Event.COMPLETE, complete);
            var content:MovieClip = MovieClip(evt.target.content);
            //Piyoクラス
            Piyo = MovieClip(content.piyo).constructor;
            setup();
            loader = null;
        }
        private function setup():void {
            //Piyoインスタンス
            piyo = new Piyo();
            addChild(piyo);
            piyo.x = 232;
            piyo.y = 380;
            piyo.scale = 5;
            drawLight();
        }
        /////////////////////////////////////////////
        //光
        /////////////////////////////////////////////
        private function drawLight():void {
            var _loader:Loader = new Loader();
            _loader.contentLoaderInfo.addEventListener(Event.INIT, initialize, false, 0, true);
            _loader.load(new URLRequest(basePath + lightPath), new LoaderContext(true));
        }
        private function initialize(evt:Event):void {
            lights = new Array();
            bitmapData = Bitmap(evt.target.content).bitmapData;
            for (var n:uint = 0; n < max; n++) {
                createLight();
            }
            addEventListener(Event.ENTER_FRAME, fall, false, 0, true);
        }
        private function createLight():void {
            var light:Light = new Light();
            addChild(light);
            light.x = 30 + Math.random()*405;
            light.y = 465 + 50 + Math.random()*465;
            light.blendMode = BlendMode.ADD;
            var bitmap:Bitmap = new Bitmap(bitmapData);
            light.addChild(bitmap);
            bitmap.smoothing = true;
            bitmap.x = -128*0.5;
            bitmap.y = -128*0.5;
            bitmap.scaleX = bitmap.scaleY = 0.5;
            lights.push(light);
            light.visible = (Math.random() < 0.5);
        }
        private function fall(evt:Event):void {
            for (var n:uint = 0; n < max; n++) {
                var light:Light = lights[n];
                light.velocity += light.acceleration;
                light.y -= light.velocity;
                if (light.y < -50) {
                    light.velocity = 0;
                    light.x = 30 + Math.random()*405;
                    light.y = 465 + 50;
                }
            }
        }
        /////////////////////////////////////////////
        //背景
        /////////////////////////////////////////////
        private function draw():void {
            drawSky();
            drawGround();
            drawSun();
        }
        private function drawSky():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(465, 350, 0.5*Math.PI, 0, 0);
            graphics.beginGradientFill(GradientType.LINEAR, [0x3F68AB, 0x77B2EE], [1, 1], [0, 255], matrix);
            graphics.drawRect(0, 0, 465, 350);
            graphics.endFill();
        }
        private function drawGround():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(465, 150, 0.5*Math.PI, 0, 350);
            graphics.beginGradientFill(GradientType.LINEAR, [0x99CC33, 0x7EB133], [1, 1], [0, 255], matrix);
            graphics.drawRect(0, 350, 465, 150);
            graphics.endFill();
        }
        private function drawSun():void {
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(200, 200, 0, -90, -90);
            graphics.beginGradientFill(GradientType.RADIAL, [0xFFFFFF, 0xFFFFFF, 0xFFFFFF], [1, 0.3, 0], [25, 102, 231], matrix);
            graphics.drawCircle(10, 10, 100);
            graphics.endFill();
            var shine:Loader = new Loader();
            addChild(shine);
            shine.alpha = 0.5;
            shine.load(new URLRequest(basePath + sunshinePath), new LoaderContext(true));
        }

    }

}


import flash.display.Sprite;

class Light extends Sprite {
    public var velocity:Number = 0;
    public var acceleration:Number;

    public function Light() {
        super();
        acceleration = Math.random()*0.4 + 0.4;
    }

}