Getting the absolute value with Math.abs() vs ?: operator

/**
 * Copyright Fumio ( http://wonderfl.net/user/Fumio )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/kJ2D
 */

package {
	import flash.display.Sprite;
	import flash.utils.getTimer;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import flash.text.TextFormatAlign;
	[SWF(width = "240",height = "180")]
	public class GettingAbs extends Sprite {
		private const AMOUNT:uint = 10000000;
		private var myVector:Vector.<Number>  = new Vector.<Number>(AMOUNT);
		private var my_txt:TextField = new TextField();
		private var label_txt:TextField = new TextField();
		private var my_fmt:TextFormat = new TextFormat();
		public function GettingAbs() {
			// Creating a TextField for display
			createTextField();
			createNumbers();
			// Starting Test
			testMath();
			testConditional();
			testMethod();
		}
		private function testMath():void {
			var _vector:Vector.<Number >  = myVector;
			var nAmount:uint = _vector.length;
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var n:Number = _vector[i];
				var nAbs:Number = Math.abs(n);
			}
			xTrace("Math.abs()",getTimer() - started);
		}
		private function testConditional():void {
			var _vector:Vector.<Number >  = myVector;
			var nAmount:uint = _vector.length;
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var n:Number = _vector[i];
				var nAbs:Number = n < 0 ? -n : n;
			}
			xTrace("?: ",getTimer() - started);
		}
		private function testMethod():void {
			var _vector:Vector.<Number >  = myVector;
			var nAmount:uint = _vector.length;
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var n:Number = _vector[i];
				var nAbs:Number = abs(n);
			}
			xTrace("Method using ?: ",getTimer() - started);
		}
		private static function abs(myValue:Number):Number {
			var nAbs:Number = myValue < 0 ? -myValue : myValue;
			return nAbs;
		}
		private function createNumbers():void {
			var nAmount:uint = AMOUNT;
			var nRange:Number = 10;
			var nMin:Number = -5;
			for (var i:uint = 0; i < nAmount; i++) {
				myVector[i] = Math.random() * nRange + nMin;
			}
		}
		private function createTextField():void {
			addChild(my_txt);
			addChild(label_txt);
			my_fmt.align = TextFormatAlign.RIGHT;
			my_txt.x +=  50;
			my_txt.defaultTextFormat = my_fmt;
			my_txt.autoSize = TextFieldAutoSize.RIGHT;
			label_txt.autoSize = TextFieldAutoSize.LEFT;
		}
		private function xTrace(_str:String,n:int):void {
			my_txt.appendText(String(n) + "\n");
			label_txt.appendText(_str + ":" + "\n");
		}
	}
}