flash on 2010-12-28

/**
 * Copyright yama3 ( http://wonderfl.net/user/yama3 )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/k6mP
 */

package {
    import flash.geom.Point;
    import flash.events.Event;
    import flash.geom.Rectangle;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import flash.geom.ColorTransform;
    import flash.display.BitmapData;
    import flash.display.Sprite;
    import flash.display.Bitmap;
    
    [SWF(frameRate='60', width='465', height='465', backgroundColor='0x0')]
    
    public class FlashTest extends Sprite {
        private var _bmp:Bitmap;
        private var _bmd:BitmapData;
        private var _bmdRect:Rectangle;
        private var _colorTransform:ColorTransform = new ColorTransform(0, 0.6, 0.9, 0.9);
        private var _rect:Rectangle;
        private var _nodeArray:Array = [];
        private var _maxNum:int = 30000;
        
        public function FlashTest() {
            this.stage.align = StageAlign.TOP_LEFT;
            this.stage.scaleMode = StageScaleMode.NO_SCALE;
            addEventListener(Event.ADDED_TO_STAGE, init);            
        }
        
        private function init(e:Event):void {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            _rect = new Rectangle(0,0,1,1);
            _bmd = new BitmapData(465, 465, false, 0x000000);
            _bmp = new Bitmap(_bmd);
            addChild(_bmp);
            _bmdRect = new Rectangle(0,0,465,465);
            for(var i:int = 0; i < _maxNum; i++) {
                var n:Node = new Node;
                n.pos_x = Math.random() * 465;
                n.pos_y = Math.random() * 465;
                _nodeArray.push(n);
            }
            addEventListener(Event.ENTER_FRAME, onEnter);
        }
        
        private function onEnter(e:Event):void {
            var gravPoint_x:Number = mouseX;
            var gravPoint_y:Number = mouseY;
            _bmd.lock();
            for(var i:int=0; i<_nodeArray.length; i++) {
                var n:Node = _nodeArray[i] as Node;
                var diff_x:Number = gravPoint_x - n.pos_x;
                var diff_y:Number = gravPoint_y - n.pos_y;
                var rad:Number = Math.atan2(diff_y, diff_x);
                var grav:Number = 10 / Math.sqrt(diff_x * diff_x + diff_y * diff_y);
                
                n.acc_x = (Math.cos(rad) * grav);
                n.acc_y = (Math.sin(rad) * grav);
                n.v_x += n.acc_x;
                n.v_y += n.acc_y;
                n.pos_x += n.v_x;
                n.pos_y += n.v_y;
                
                n.acc_x *= 0.98;
                n.acc_y *= 0.98;
                n.v_x *= 0.96;
                n.v_y *= 0.96;
                
                if(n.pos_x > 465)
                n.pos_x = 0;
                else if(n.pos_x < 0)
                n.pos_x = 465;
                if(n.pos_y < 0)
                n.pos_y = 0;
                else if(n.pos_y < 0)
                n.pos_y = 465;
                
                _rect.x = n.pos_x;
                _rect.y = n.pos_y;
                
                _bmd.fillRect(_rect, 0xffffff);
            }
            _bmd.colorTransform(_bmdRect, _colorTransform);
            _bmd.unlock();
        }
    }
}

import flash.geom.Point;

class Node {
    public var acc_x:Number = 0;
    public var acc_y:Number = 0;
    public var v_x:Number = 0;
    public var v_y:Number = 0;
    public var pos_x:Number = 0;
    public var pos_y:Number = 0;
}