flash on 2010-5-15

/**
 * Copyright kihon ( http://wonderfl.net/user/kihon )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/jREN
 */

package
{
	import com.bit101.components.PushButton;
	import flash.display.Sprite;
	import flash.events.Event;
	import frocessing.math.Random;
	import jp.progression.commands.Func;
	import jp.progression.commands.lists.SerialList;
	import jp.progression.commands.Wait;
	
	public class Main extends Sprite
	{
		private var data:Array;
		private var SIZE:int = 5;
		private var num:int = 80;
		private var list:SerialList = new SerialList();
		
		public function Main()
		{
			graphics.beginFill(0xF0F0F0);
			graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
			graphics.endFill();
			
			data = new Array(num);
			for (var i:int = 0; i < data.length; i++)
			{
				var rect:Rect = new Rect(SIZE);
				rect.x = rect.value = i * SIZE;
				rect.y = i * SIZE;
				addChild(rect);
				data[i] = rect;
			}
			init();

			new PushButton(this, 185, 400, "execute", execute);
		}
		
		private function execute(event:Event):void
		{
			if (list.state == 2) return;
			list = new SerialList();
			
			init();
			sort();
			list.execute();
		}
		
		private function init():void
		{
			var random:Array = Random.shakedIntegers(num);
			for (var i:int = 0; i < data.length; i++)
			{
				data[i].x = random[i] * SIZE;
			}
		}
		
		private function sort():void
		{	
			var bucket:Array = [];
			
			for (var d:int = 0; d < 3; d++)
			{
				for (var i:int = 0; i < 10; i++)
				{
					bucket[i] = [];
				}
				
				var divisor:int = Math.pow(10, d);
				for (i = 0; i < data.length; i++)
				{
					var value:int = data[i].value / divisor % 10;
					bucket[value].push(data[i]);
				}
				
				var step:int = 0;
				for (var j:int = i = 0; i < bucket.length; i++)
				{
					for each (var item:Rect in bucket[i])
					{
						trace(step);
						list.addCommand(new Func(function(rect:Rect, tx:int):void { rect.x = tx; }, [item, step * SIZE]));
						list.addCommand(new Wait(20 / 1000.0));
						data[j++] = item;
						step++;
					}
				}
			}
		}
	}
}

import flash.display.Sprite;
import flash.filters.DropShadowFilter;

class Rect extends Sprite
{
	public var value:int;
	
	public function Rect(size:int)
	{
		graphics.beginFill(0x0);
		graphics.drawRect(0, 0, size, size);
		graphics.endFill();
		
		this.filters = [new DropShadowFilter(2)];
	}
}