Creating Vectors containing elements

/**
 * Copyright Fumio ( http://wonderfl.net/user/Fumio )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/jDN9
 */

package {
	import flash.display.Sprite;
	import flash.utils.getTimer;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	[SWF(width = "240",height = "180")]
	public class CreatingVectors extends Sprite {
		private const MAX_NUMBER:int = 700000;
		private var i:int;
		private var started:int;
		private var my_txt:TextField = new TextField();
		private var label_txt:TextField = new TextField();
		public function CreatingVectors() {
			// Creating a TextField for display
			createTextField();
			// Starting test
			castingArray();
			pushEach();
			pushAll();
			setToIndex();
			setToIndex2();
			newSyntax();
		}
		private function castingArray():void {
			started = getTimer();
			for (i = 0; i < MAX_NUMBER; i++) {
				var myVector:Vector.<int >  = Vector.<int > ([0,1,2,3,4]);
			}
			xTrace(getTimer() - started);
		}
		private function newSyntax():void {
			started = getTimer();
			for (i = 0; i < MAX_NUMBER; i++) {
				var myVector:Vector.<int >  = new <int >[0,1,2,3,4];
			}
			xTrace(getTimer() - started);
		}
		private function pushEach():void {
			started = getTimer();
			for (i = 0; i < MAX_NUMBER; i++) {
				var myVector:Vector.<int >  = new Vector.<int >();
				myVector.push(0);
				myVector.push(1);
				myVector.push(2);
				myVector.push(3);
				myVector.push(4);
			}
			xTrace(getTimer() - started);
		}
		private function pushAll():void {
			started = getTimer();
			for (i = 0; i < MAX_NUMBER; i++) {
				var myVector:Vector.<int >  = new Vector.<int >();
				myVector.push(0, 1, 2, 3, 4);
			}
			xTrace(getTimer() - started);
		}
		private function setToIndex():void {
			started = getTimer();
			for (i = 0; i < MAX_NUMBER; i++) {
				var myVector:Vector.<int >  = new Vector.<int >();
				myVector[0] = 0;
				myVector[1] = 1;
				myVector[2] = 2;
				myVector[3] = 3;
				myVector[4] = 4;
			}
			xTrace(getTimer() - started);
		}
		private function setToIndex2():void {
			started = getTimer();
			for (i = 0; i < MAX_NUMBER; i++) {
				var myVector:Vector.<int >  = new Vector.<int > (5);
				myVector[0] = 0;
				myVector[1] = 1;
				myVector[2] = 2;
				myVector[3] = 3;
				myVector[4] = 4;
			}
			xTrace(getTimer() - started);
		}
		private function createTextField():void {
			addChild(my_txt);
			addChild(label_txt);
			my_txt.x +=  80;
			my_txt.autoSize = TextFieldAutoSize.RIGHT;
			label_txt.autoSize = TextFieldAutoSize.LEFT;
			label_txt.text = "01      casting Array:\n02-01 push each:\n02-02 push all:\n03-01 set to index:\n03-02 set to index (length):\n04      new syntax:";
		}
		private function xTrace(n:int):void {
			my_txt.appendText(String(n) + "\n");
		}
	}
}