stripes

/**
 * Copyright jerryrom ( http://wonderfl.net/user/jerryrom )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/i1HE
 */

package 
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.filters.BlurFilter;
	import flash.geom.Matrix;
	import flash.geom.Rectangle;
	import flash.geom.Point;
	
	public class Main extends Sprite 
	{
		private var bmpdata:BitmapData;
		private var matrix:Matrix;
		private var circle:Sprite;
		private var filter:BlurFilter;
		private var rect:Rectangle;
		
		[SWF(width="465", height="465", framerate="30")]
		public function Main():void 
		{
			if (stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
		
		private function init(e:Event = null):void 
		{
			removeEventListener(Event.ADDED_TO_STAGE, init);
			bmpdata = new BitmapData(465, 465, false, 0xFFFFFF);
			addChild(new Bitmap(bmpdata, "auto", true));
			
			circle = new Sprite();
			circle.graphics.beginFill(0x000000);
			circle.graphics.drawCircle(465/2, 0, 10);
			circle.graphics.endFill();

			matrix = new Matrix();
			matrix.identity();
			
			filter = new BlurFilter(2, 2, 1);
			addEventListener(Event.ENTER_FRAME, enterframe);
			
			rect = new Rectangle(465/2-5, 0, 20, 465);
		}
		
		private function enterframe(e:Event):void 
		{
			var x:Number = (Math.random() - 0.5)*2;
			var y:Number = Math.random()*5;
			matrix.translate(x, y);
			bmpdata.draw(circle, matrix);
			bmpdata.applyFilter(bmpdata, rect, new Point(Math.random()*465, 0), filter);
		}
	}	
}