forked from: 重力マウス（100万パーティクル）

/**
 * Copyright Thy ( http://wonderfl.net/user/Thy )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/fwzb
 */

// forked from clockmaker's 重力マウス（100万パーティクル）
// forked from cjcat2266's 重力マウス（プチ軽量化：25万パーティクル）
// forked from clockmaker's 重力マウス（プチ軽量化：10万パーティクル）
// forked from coppieee's 重力マウス（さらに軽量化してみた）
// forked from paq's forked from: 重力マウス（ちょっぴり軽量化してみた）
// forked from fumix's 重力マウス（リンクリストにしてみた）
// forked from undo's 重力マウス
//　リンクリストにしてみたけどそんなに速くない？？
//_bmd.fillRect()を_bmd.setPixel()に変更。
//sin(),cos(),atan2(),sqrt()を排除。
// Add final class / mouseEnalbled = false by clockmaker
// CJ Cat: Used vector instead of linked list.
// clockmaker: while文の処理を4回コピペしてイテレーションの回数を減らす 100万で30fps (FP10.1 Release))
package
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.geom.ColorTransform;
	import flash.geom.Point;
	import flash.geom.Rectangle;
	import flash.utils.ByteArray;
	import net.hires.debug.Stats;

	[SWF(frameRate='48', width='465', height='465', backgroundColor='0x0')]

	public class Main extends Sprite {
		private var _bmp:Bitmap;
		private var _bmd:BitmapData;
		private var _bmdRect:Rectangle;
		private var _colorTransform:ColorTransform = new ColorTransform(0.97, 0.9, 0.9, 1.0);

		private const _maxNum:int = 1000000;
		private var _cnt:int = 0;
		
		private const _particleData:Vector.<Number> = new Vector.<Number>(_maxNum * 4, true);
		private var ba:ByteArray
		

		public function Main() {
			if(stage) init(null);
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}
		
		private function init(evt:Event):void {
			removeEventListener(Event.ADDED_TO_STAGE, init);
			
			this.stage.align = StageAlign.TOP_LEFT;
			this.stage.scaleMode = StageScaleMode.NO_SCALE;
			this.stage.quality = "low";
			this.mouseEnabled = false;
			this.mouseChildren = false;
		
			_bmd = new BitmapData(465, 465, false, 0x0);
			_bmp = new Bitmap(_bmd);
			addChild(_bmp);
			this._bmdRect = _bmd.rect;
			
			var i0:int, i1:int, i2:int, i3:int;
			i0 = 0;
			while (i0 < _maxNum) {
				i1 = i0;
				i2 = ++i1;
				i3 = ++i2;
				i3++;
				
				_particleData[i0] = Math.random() * 465;
				_particleData[i1] = Math.random() * 465;
				_particleData[i2] = 0;
				_particleData[i3] = 0;
				
				i0 = ++i3;
			}
			
			ba = new ByteArray()
			ba.length = 465*465
			
			addChild(new Stats());
			addEventListener(Event.ENTER_FRAME, onEnter);
		}

		private function onEnter(evt:Event):void {
			var gravPoint_x:Number = mouseX;
			var gravPoint_y:Number = mouseY;
			var calc:Boolean = Boolean((_cnt & 7) == 0) /*_cnt % 7 == 0;*/
			
			this._bmd.lock();
			
			var diff_x:Number, diff_y:Number, acc:Number
			var i0:uint, i1:uint, i2:uint, i3:uint, j0:uint, j1:uint, j2:uint, j3:uint, k0:uint, k1:uint, k2:uint, k3:uint, l0:uint, l1:uint, l2:uint, l3:uint;
			i0 = 0;
			while (i0 < _maxNum)
			{
				i1 = i0;
				i2 = ++i1;
				i3 = ++i2;
				j0 = ++i3;
				j1 = ++j0;
				j2 = ++j1;
				j3 = ++j2;
				k0 = ++j3;
				k1 = ++k0;
				k2 = ++k1;
				k3 = ++k2;
				l0 = ++k3;
				l1 = ++l0;
				l2 = ++l1;
				l3 = ++l2;
				++l3;
				
				
				if(calc){
					
					diff_x = gravPoint_x - _particleData[i0];
					diff_y = gravPoint_y - _particleData[i1];
					acc = 200 / (diff_x * diff_x + diff_y * diff_y);
					_particleData[i0] += (_particleData[i2] = _particleData[i2]*.96 + acc * diff_x)
					_particleData[i1] += (_particleData[i3] = _particleData[i3]*.96 + acc * diff_y)
					//
					diff_x = gravPoint_x - _particleData[j0];
					diff_y = gravPoint_y - _particleData[j1];
					acc = 200 / (diff_x * diff_x + diff_y * diff_y);
					_particleData[j0] += (_particleData[j2] = _particleData[j2]*.96 + acc * diff_x)
					_particleData[j1] += (_particleData[j3] = _particleData[j3] *.96 + acc * diff_y)
					//
					diff_x = gravPoint_x - _particleData[k0];
					diff_y = gravPoint_y - _particleData[k1];
					acc = 200 / (diff_x * diff_x + diff_y * diff_y);
					_particleData[k0] += (_particleData[k2] = _particleData[k2]*.96 + acc * diff_x)
					_particleData[k1] += (_particleData[k3] = _particleData[k3] *.96 + acc * diff_y)
					//
					diff_x = gravPoint_x - _particleData[l0];
					diff_y = gravPoint_y - _particleData[l1];
					acc = 200 / (diff_x * diff_x + diff_y * diff_y);
					_particleData[l0] += (_particleData[l2] = _particleData[l2]*.96 + acc * diff_x)
					_particleData[l1] += (_particleData[l3] = _particleData[l3] *.96 + acc * diff_y)
					
				} else 
				{
					_particleData[i0] += (_particleData[i2])
					_particleData[i1] += (_particleData[i3])
					//
					_particleData[j0] += (_particleData[j2])
					_particleData[j1] += (_particleData[j3])
					//
					_particleData[k0] += (_particleData[k2])
					_particleData[k1] += (_particleData[k3])
					//
					_particleData[l0] += (_particleData[l2])
					_particleData[l1] += (_particleData[l3])
					
				}
				
				ba.position = uint(_particleData[i0]) * 465 + uint(_particleData[i1])
				ba.writeBoolean(true)
				ba.position = uint(_particleData[j0]) * 465 + uint(_particleData[j1])
				ba.writeBoolean(true)
				ba.position = uint(_particleData[k0]) * 465 + uint(_particleData[k1])
				ba.writeBoolean(true)
				ba.position = uint(_particleData[l0]) * 465 + uint(_particleData[l1])
				ba.writeBoolean(true)
				
				
				
				i0 = ++l3;
			}
			
			// draw pixels and apply col
			ba.position = 0
			i1 = 0 // re-use uint for loop
			while (i1 < 465)
			{
				i0=0
				while (i0 < 465)
				{
					/*this._bmd.setPixel(i1,i0,uint(ba.readBoolean())*0xFFFFFF)*/
					if (ba.readBoolean())
					{
						this._bmd.setPixel(i1,i0,0xFFFFFF)
					} else 
					{
						this._bmd.setPixel(i1,i0, ((this._bmd.getPixel(i1,i0)>>16) * .9) << 16)
					}
					++i0
				}
				++i1
			}
			ba.clear()
			ba.length = 465 * 465
			
			this._bmd.unlock();
			_cnt++;
		}
	}
}