flash on 2011-9-2

/**
 * Copyright wh0 ( http://wonderfl.net/user/wh0 )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/dI1v
 */

package {
    import flash.display.*;
    import flash.events.*;
    import flash.media.*;
    import flash.ui.*;
    import com.greensock.*;
    import com.greensock.easing.*;
    public class FlashTest extends Sprite {
        
        private var camera:Camera;
        private var video:Video;
        private var flash:Shape;
        private var photos:Array;
        
        public function FlashTest() {
            Wonderfl.disable_capture();
            stage.scaleMode = StageScaleMode.NO_SCALE;
            stage.align = StageAlign.TOP_LEFT;
            camera = Camera.getCamera();
            camera.setMode(stage.stageWidth, stage.stageHeight, stage.frameRate);
            video = new Video(stage.stageWidth, stage.stageHeight);
            video.attachCamera(camera);
            addChild(video);
            flash = new Shape();
            flash.graphics.beginFill(0xffffff);
            flash.graphics.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
            flash.alpha = 0;
            stage.addChild(flash);
            photos = [];
            stage.addEventListener(KeyboardEvent.KEY_DOWN, keyDown);
            stage.addEventListener(TouchEvent.TOUCH_TAP, touchTap);
        }
        
        private function keyDown(e:KeyboardEvent):void {
            if (e.keyCode == Keyboard.SPACE) execute();
        }
        
        private function touchTap(e:TouchEvent):void {
            execute();
        }
        
        private function execute():void {
            flash.alpha = 1;
            var bd:BitmapData = new BitmapData(stage.stageWidth, stage.stageHeight, false);
            bd.draw(video);
            var b:Bitmap = new Bitmap(bd);
            var s:Sprite = new Sprite();
            s.graphics.beginFill(0xffffff);
            s.graphics.drawRect(-16, -16, stage.stageWidth + 32, stage.stageHeight + 32);
            s.addChild(b);
            addChild(s);
            TweenLite.to(flash, 1, {alpha: 0});
            TweenLite.to(s, 1, {x: stage.stageWidth * 0.1 * photos.length, y: stage.stageHeight * 0.81, scaleX: 0.2, scaleY: 0.2, rotation: 10});
            photos.push(s);
        }
        
    }
}