forked from: 3DPlaneにプログラム描画の画像貼りつけ練習

/**
 * Copyright tepe ( http://wonderfl.net/user/tepe )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/cckb
 */

// forked from siouxcitizen's 3DPlaneにプログラム描画の画像貼りつけ練習
// forked from siouxcitizen's Papervision3DTest01　：3D板を回転させる
//
//以下コードとサイトを参考にさせていただきました。
//dots
//http://wonderfl.net/c/q7hZ
//
//Flashの描画速度をBitmapDataクラスを使って上げる方法
//http://sipo.jp/blog/2009/12/flashbitmapdata.html
//
package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.geom.Matrix;

    import org.papervision3d.view.Viewport3D;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.materials.ColorMaterial;
    import org.papervision3d.materials.BitmapMaterial;
    import org.papervision3d.render.BasicRenderEngine;
 
    [SWF(width="500", height="500", frameRate="60", backgroundColor="#66CCFF")]
 
    public class MoviePlane extends Sprite
    {
        private var container : Sprite;
        private var viewport  : Viewport3D;
        private var scene     : Scene3D;
        private var camera    : Camera3D;
        private var material  : BitmapMaterial;
        private var planeObj  : Plane; 
        private var renderer  : BasicRenderEngine;

        private var planeSize : int = 320;//Planeオブジェクト1辺の長さ
        private var segment   : int = 3;  //面の分割数

        //MoviePlaneクラスのコンストラクタ
        public function MoviePlane():void
        {          
            //ビューポート生成
            viewport = new Viewport3D(500, 500, false, true);
            addChild(viewport);

            //シーン生成
            scene = new Scene3D();

            //レンダリングエンジン生成
            renderer = new BasicRenderEngine();

            //テクスチャ用画像を作成
            var recipe:Recipe = new Recipe();
            recipe.width = 16;
            recipe.height = 16;
            recipe.scale = 20.0;
            recipe.data = [0,0,0,0,0,0,1,1,1,1,0,0,0,0,0,0,
                           0,0,0,0,0,1,1,1,1,1,1,0,0,0,0,0,
                           0,0,0,0,1,1,1,1,1,1,1,1,0,0,0,0,
                           0,0,0,1,1,1,1,1,1,1,1,1,1,0,0,0,
                           0,0,1,2,2,1,1,1,1,1,1,2,2,1,0,0,
                           0,1,1,1,3,2,1,1,1,1,2,3,1,1,1,0,
                           0,1,1,1,3,2,2,2,2,2,2,3,1,1,1,0,
                           1,1,1,1,3,2,3,1,1,3,2,3,1,1,1,1,
                           1,1,1,1,3,3,3,1,1,3,3,3,1,1,1,1,
                           1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,
                           0,1,1,1,1,3,3,3,3,3,3,1,1,1,1,0,
                           0,0,0,0,3,3,3,3,3,3,3,3,0,0,0,0,
                           0,0,0,0,3,3,3,3,3,3,3,3,2,2,0,0,
                           0,0,2,2,2,3,3,3,3,3,2,2,2,2,2,0,
                           0,0,2,2,2,2,3,3,3,2,2,2,2,2,2,0,
                           0,0,0,0,2,2,2,0,0,2,2,2,2,2,0,0];
            recipe.pallet.push(0xFFff0000, 0xFF4090c0, 0xFF305080, 0xFFa0fff0);//0xFFa0fff0 0xFF4090c0
            recipe.transparent = 0;
            var textureOnPlane : DotDraw = new DotDraw(recipe);

            //bitmapDataを用意する
            var bitmapData:BitmapData = new BitmapData(320, 320, true, 0x00000000); // 透明なBitmapDataを用意
            var matrix:Matrix = new Matrix();   // 表示位置はMatrixで指定する
            matrix.translate(0, 0);   // (0, 0)の位置に描画する設定にする
            bitmapData.draw(textureOnPlane, matrix);    // spriteをbitmapDataに描画する

            //マテリアル設定
            material = new BitmapMaterial(bitmapData, false);
            material.doubleSided = true;

            //Planeオブジェクト生成
            planeObj= new Plane(material, planeSize, planeSize, segment, segment);
            scene.addChild(planeObj);

            //カメラ設定
            camera = new Camera3D();
            camera.z = -planeSize;
            camera.focus = 50;
            camera.zoom = 1;
 
            //マウスイベント処理用リスナを設定
            stage.addEventListener(Event.ENTER_FRAME, _enterframe);
        }

        //マウスイベント処理
        private function _enterframe(e:Event):void{
            planeObj.rotationX=viewport.mouseX;
            planeObj.rotationY=viewport.mouseY;
            renderer.renderScene(scene, camera, viewport);
        }
    }
}

class Recipe {
    public var width:uint = 0;
    public var height:uint = 0;
    public var scale:Number = 1.0;
    public var data:/*uint*/Array = new Array();
    public var pallet:/*uint*/Array = new Array();
    public var transparent:int = -1;
}

import flash.display.Sprite;
class DotDraw extends Sprite {
    public function DotDraw(recipe:Recipe) {
        for (var index:uint = 0; index < recipe.width * recipe.height; ++index) {
            var x:uint = index % recipe.width;
            var y:uint = uint(index / recipe.width);
            
            var datum:uint = recipe.data[x + (y * recipe.width)];
            var color:uint = recipe.pallet[datum];
            var scale:Number = recipe.scale;
            var alpha:Number = (datum == recipe.transparent) ? 0.0 : 1.0;
            
            this.graphics.beginFill(color, alpha);
            this.graphics.drawRect(x * scale, y * scale, scale, scale);
            this.graphics.endFill();
        }
    }

}