Project Euler 111

/**
 * Copyright uwi ( http://wonderfl.net/user/uwi )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/aOax
 */

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.utils.getTimer;
    // @see http://projecteuler.net/index.php?section=problems&id=111
    public class Euler111 extends Sprite {
        private var _tf : TextField;
  
        public function Euler111() {
            _tf = new TextField();
            _tf.width = 465;
            _tf.height = 465;
            addChild(_tf);
            
            var s : int = getTimer();
            _tf.appendText("" + solve() + "\n");
            var g : int = getTimer();
            _tf.appendText("" + (g - s) + " ms\n");
        }
        
        private const KLIM : Number = 1000000000;
        private const ZORO : Number = 1111111111;
        
        private function solve() : Number
        {
            var sum : Number = 0;
            var i : int, j : int, k : Number, l : int, m : Number, n : Number;
            for(i = 1;i <= 9;i++){
                for(j = 0;j <= 9;j++){
                    for(k = 1;k <= KLIM;k *= 10){
                        n = i * (ZORO - k) + j * k;
                        if(isPrime(n) && n >= KLIM){
                            sum += n;
                            _tf.appendText("" + n + "\n");
                        }
                    }
                }
            }
            
            for each(i in [0, 2, 8]){
                for(j = 0;j <= 9;j++){
                    for(k = 1;k <= KLIM;k *= 10){
                        for(l = 0;l <= 9;l++){
                            for(m = k * 10;m <= KLIM;m *= 10){
                                n = i * (ZORO - k - m) + j * k + l * m;
                                if(isPrime(n) && n >= KLIM){
                                    sum += n;
                                    _tf.appendText("" + n + "\n");
                                }
                            }
                        }
                    }
                }
            }
            return sum;
        }
        
        private function isPrime(n : Number) : Boolean
        {
            var sq : int = Math.sqrt(n);
            for(var i : int = 2;i <= sq;i++){
                if(n % i == 0)return false;
            }
            return true;
        }
    }
}