Project Euler 50

/**
 * Copyright uwi ( http://wonderfl.net/user/uwi )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/hweu
 */

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.utils.getTimer;
    // @see http://projecteuler.net/index.php?section=problems&id=50
    public class Euler50 extends Sprite {
        private var _tf : TextField;
  
        public function Euler50() {
            _tf = new TextField();
            _tf.width = 465;
            _tf.height = 465;
            addChild(_tf);
            
            var s : int = getTimer();
            t(solve());
            var g : int = getTimer();
            t((g - s) + " ms");
        }

        private function solve() : int
        {
            var primes : Array = doEratosthenes(1000000);
            var pmap : Object = {};
            for each(var p : int in primes){
                pmap[p] = p;
            }
            
            var maxlen : int = 0;
            var max : int = 0;
            for(var i : int = 0;i < primes.length - maxlen;i++){
                var sum : int = 0;
                for(var j : int = i;j < primes.length;j++){
                    sum += primes[j];
                    if(sum > 1000000)break;
                    if(j - i + 1 > maxlen && pmap[sum]){
                        maxlen = j - i + 1;
                        max = sum;
                    }
                }
            }
            t("maxlen : " + maxlen);
            return max;
        }

        private static function doEratosthenes(n : int) : Array
        {
            var ar : Vector.<uint> = new Vector.<uint>(n / 2 - 1);
            var i : int;
            for(i = 0;i < ar.length;i++)ar[i] = 1;
            
            var sq : int = (Math.sqrt(n) - 3) >> 1;
            for(var p : int = 0;p <= sq;p++){
                if(ar[p] == 1){
                    var m : int = (p << 1) + 3;
                    var m2 : int = m << 1;
                    for(var mm : int = m * m;mm <= n;mm += m2){
                        ar[(mm - 3) >> 1] = 0;
                    }
                }
            }
            var ret : Array = [2];
            for(i = 0;i < ar.length;i++){
                if(ar[i] == 1)ret.push((i << 1) + 3);
            }
            return ret;
        }
        
        private function t(o : *) : void
	{
            _tf.appendText("" + o + "\n");
	}
    }
}