Project Euler 231

/**
 * Copyright uwi ( http://wonderfl.net/user/uwi )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/5QgF
 */

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.utils.getTimer;
    // @see http://projecteuler.net/index.php?section=problems&id=231
    public class Euler231 extends Sprite {
        private var _tf : TextField;
  
        public function Euler231() {
            _tf = new TextField();
            _tf.width = 465;
            _tf.height = 465;
            addChild(_tf);
            
            var s : int = getTimer();
            _tf.appendText("" + solve(20000000, 5000000) + "\n");
            var g : int = getTimer();
            _tf.appendText("" + (g - s) + " ms\n");
        }
        
        private function solve(N : int, K : int) : Number
        {
            var primes : Array = doEratosthenes(N);
            var sum : Number = 0;
            for each(var p : int in primes){
                var nf : int = 0;
                for(var f : Number = p;f <= N;f *= p){
                    nf += int(N / f) - int((N - K) / f) - int(K / f);
                }
                sum += p * nf;
            }
            
            return sum;
        }
        
        private static function doEratosthenes(n : int) : Array
        {
            var ar : Vector.<uint> = new Vector.<uint>(n / 2 - 1);
            var i : int;
            for(i = 0;i < ar.length;i++)ar[i] = 1;
            
            var sq : int = (Math.sqrt(n) - 3) >> 1;
            for(var p : int = 0;p <= sq;p++){
                if(ar[p] == 1){
                    var m : int = 2 * p + 3;
                    for(var mm : int = m * m;mm <= n;mm += 2 * m){
                        ar[(mm - 3) >> 1] = 0;
                    }
                }
            }
            var ret : Array = [2];
            for(i = 0;i < ar.length;i++){
                if(ar[i] == 1)ret.push(2 * i + 3);
            }
            return ret;
        }    }
}