/**
* Copyright mutantleg ( http://wonderfl.net/user/mutantleg )
* MIT License ( http://www.opensource.org/licenses/mit-license.php )
* Downloaded from: http://wonderfl.net/c/YTYt
*/
package {
import flash.events.Event;
import flash.display.Sprite;
public class FlashTest extends Sprite {
public function FlashTest() {
cw=32;ch=32;
initEmpty(16,16);
var i:int;
for (i=0;i<64;i+=1)
{ setTile(Math.random()*16,Math.random()*16, Math.random()*5); }
for (i=0;i<16;i+=1)
{ setTile(i, 0,1); setTile(0,i,1); setTile(i,14,1); setTile(14,i,1); }
myObj = new xObj();
myObj.cx = 230; myObj.cy = 230;
stage.addEventListener(Event.ENTER_FRAME, onEnter);
}//ctor
public var vecGrid:Vector.<int>;
public var mw:int = 0; public var mh:int = 0;
public var cw:Number = 32; public var ch:Number = 32;
public function initEmpty(aw:int, ah:int):void
{ mw=aw; mh=ah; vecGrid = new Vector.<int>(aw*ah, false); }
public function setTile(ax:int, ay:int, t:int):void
{ if (ax<0||ax>=mw||ay<0||ay>=mh) {return;} vecGrid[ay*mw+ax]=t; }
public function getTile(ax:int, ay:int ):int
{ if (ax<0||ax>=mw||ay<0||ay>=mh) {return 0;} return vecGrid[ay*mw+ax]; }
public function isWall(ax:int, ay:int):Boolean
{ if (ax<0||ax>=mw||ay<0||ay>=mh){return true;} return vecGrid[ay*mw+ax] > 0; }
public var myObj:xObj;
public function onEnter(e:Event):void
{
graphics.clear();
graphics.lineStyle(2, 0);
var ax:Number; var ay:Number;
var i:int; var k:int; var yt:int; var t:int;
for (i=0;i<mh;i++)
{
yt = i * mw;
for (k=0;k<mw;k++)
{
t = vecGrid[k+yt];
if (t<=0) { continue; }
graphics.beginFill(0x404040, 1);
ax=k*cw;ay=i*ch;
if (t==2) // `/
{
graphics.moveTo(ax,ay);
graphics.lineTo(ax+cw,ay);
graphics.lineTo(ax, ay+ch);
graphics.lineTo(ax,ay);
}
else if (t == 3) // \`
{
graphics.moveTo(ax,ay);
graphics.lineTo(ax+cw,ay);
graphics.lineTo(ax+cw, ay+ch);
graphics.lineTo(ax,ay);
}
else if (t == 4) // .\
{
graphics.moveTo(ax,ay+ch);
graphics.lineTo(ax+cw,ay+ch);
graphics.lineTo(ax,ay);
}
else if (t == 5) // /.
{
graphics.moveTo(ax+cw,ay+ch);
graphics.lineTo(ax,ay+ch);
graphics.lineTo(ax+cw,ay);
}
else // #
{ graphics.drawRect(ax,ay,cw,ch); }
graphics.endFill();
continue;
}//nextk
}//nexti
var a:xObj;
a = myObj;
var ms:Number; ms = 0.2;
var ta:Number;
ta = Math.atan2(stage.mouseY-a.cy, stage.mouseX-a.cx);
a.vx += Math.cos(ta)*ms;
a.vy += Math.sin(ta)*ms;
ms = 8;
if (a.vx > ms) { a.vx = ms; } else if (a.vx < -ms) { a.vx = -ms; }
if (a.vy > ms) { a.vy = ms; } else if (a.vy < -ms) { a.vy = -ms; }
gridTest(a);
gridTest(a);
a.cx +=a.vx;
a.cy +=a.vy;
graphics.drawCircle(a.cx,a.cy, a.rad);
}//onenter
public function getMag(ax:Number, ay:Number):Number
{ return Math.sqrt(ax * ax + ay * ay); }
public function gridTest(a:xObj):void
{
var i:int; var k:int;
var ax:int; var ay:int;
var ix:Number; var iy:Number;
var d:Number; var ta:Number;
var nx:Number; var ny:Number;
var dot:Number;
var bx:Number; var by:Number;
var t:int;
ax = a.cx / cw; ay = a.cy / ch;
for (i = -1; i <= 1; i += 1)
for (k = -1; k <= 1; k += 1)
{
//if (isWall(ax+k, ay+i)==false) { continue; }
t = getTile(ax+k,ay+i);
if (t<=0) {continue; }
bx = (ax+k)*cw; by = (ay+i)*ch;
if (t == 2) { if (a.cx < bx || a.cy < by) { t=1;} }
else if (t == 3) { if ((a.cx > bx+cw) || a.cy < by) { t=1;} }
else if (t == 4) { if (a.cx < bx || (a.cy > by+ch)) { t=1;} }
else if (t == 5) { if ((a.cx > bx+cw) || (a.cy > by+ch)) { t=1;} }
if (t >1 && t <=5)
{
if (t == 2 || t == 5)
{ getCloseLine(a.cx,a.cy,bx+cw,by, bx,by+ch); }
else
{ getCloseLine(a.cx,a.cy,bx,by, bx+cw,by+ch); }
ix=closex; iy = closey;
}
else
{
if (a.cx < bx) {ix = bx; }
else if (a.cx > bx+cw) { ix = bx+ cw; }
else {ix=a.cx;}
if (a.cy < by) {iy = by; }
else if (a.cy > by+ch) { iy = by+ ch; }
else {iy=a.cy;}
}//endif
d = getMag(a.cx-ix, a.cy-iy);
if (d > a.rad) { continue; }
ta = Math.atan2(iy - a.cy, ix - a.cx);
a.cx += Math.cos(ta) * (d - a.rad)*0.5;
a.cy += Math.sin(ta) * (d - a.rad)*0.5;
nx = Math.cos(ta); ny = Math.sin(ta);
dot = a.vy * ny + a.vx * nx;
if (dot > 0)
{ a.vx -= nx * dot; a.vy -= ny * dot; }
}//nextki
}//gridtest
public var closex:Number = 0;
public var closey:Number = 0;
public function getCloseLine(px:Number, py:Number,
x0:Number, y0:Number, x1:Number, y1:Number):Number
{
var t:Number; var ax:Number; var ay:Number;
var bx:Number; var by:Number;
ax = px - x0; ay = py - y0;
bx = x1 - x0; by = y1 - y0;
t = (ax*bx + ay*by) / (bx*bx + by*by);
if (t < 0) { t = 0;} if (t > 1) { t = 1; }
closex = x0 + (x1 - x0) * t;
closey = y0 + (y1 - y0) * t;
return t;
}//getclose
}//classend
}
internal class xObj
{
public var cx:Number = 0; public var cy:Number = 0;
public var vx:Number = 0; public var vy:Number = 0;
public var rad:Number = 16;
}//xobj
