flash on 2015-11-15

/**
 * Copyright mutantleg ( http://wonderfl.net/user/mutantleg )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/M8F1
 */

package {
    
    import flash.events.Event;
    import flash.display.Sprite;
    public class FlashTest extends Sprite {
        public function FlashTest() {
            
            vecLine = new Vector.<xLine>(0, false);
            var i:int; var a:xLine;
            for (i =0; i<32;i+=1)
            {
              a = new xLine(0,0,0,0);
              a.x0 = Math.random()*400;
              a.y0 = Math.random()*400;
              a.x1 = a.x0+Math.random()*140-70;
              a.y1 = a.y0+Math.random()*140-70;
               vecLine.push(a);  
            }//nexti
 
             addRect(4,4,430,430);           
            
            myBall = new xBall();
             myBall.cx=230; myBall.cy=240;
            
            stage.addEventListener(Event.ENTER_FRAME, onEnter);
        }//ctor
        
        public function addRect(ax:Number,ay:Number, aw:Number, ah:Number):void
        {
            vecLine.push(new xLine(ax,ay, ax+aw, ay));
            vecLine.push(new xLine(ax,ay+ah, ax+aw, ay+ah));
            vecLine.push(new xLine(ax,ay, ax, ay+ah));
            vecLine.push(new xLine(ax+aw,ay, ax+aw, ay+ah));
       
        }//addrect
        
        
        public var myBall:xBall;
        
        public var vecLine:Vector.<xLine>;
        
        public function onEnter(e:Event):void
        {
            var ms:Number;
            var ta:Number;
            var a:xBall;
            var d:Number;
            var mx:Number; var my:Number;
            mx = stage.mouseX; my = stage.mouseY;
            a = myBall;
            ta = Math.atan2(my-a.cy, mx-a.cx);
            d = getMag(mx-a.cx, my-a.cy);
            
             ms = 0.3;
            if (d < 30) {ms=0; a.vx*=0.9; a.vy*=0.9;}
            a.vx += Math.cos(ta)*ms;
            a.vy += Math.sin(ta) *ms;
            a.vx *= 0.99;
            a.vy *= 0.99;
       
            lineTest(a);
            a.cx += a.vx;
            a.cy += a.vy;
            
            
            graphics.clear();
            graphics.lineStyle(2, 0);
            graphics.drawCircle(a.cx, a.cy, a.rad);
 
            var i:int; var num:int; var w:xLine;           
            num = vecLine.length;      
            for (i = 0; i < num; i += 1)
            {
              w = vecLine[i];
               graphics.moveTo(w.x0, w.y0);
               graphics.lineTo(w.x1, w.y1);
            }//nexti
                
        }//onenter
        
        
      public function lineTest(m:xBall):void
      {
        var i:int; var num:int; var a:xLine;
        var nx:Number; var ny:Number; var ta:Number;
        var d:Number; var dot:Number;    
        num=vecLine.length;
        for (i=0;i<num;i+=1)
        {
            a = vecLine[i];
           getClosePoint(m.cx,m.cy, a);
           d = getMag(m.cx-closex, m.cy-closey);
           if (d > m.rad) { continue; }
           
            ta = Math.atan2(closey - m.cy, closex - m.cx);
            m.cx += Math.cos(ta) * (d - m.rad);
            m.cy += Math.sin(ta) * (d - m.rad);
            nx = Math.cos(ta); ny = Math.sin(ta);  

           dot = m.vy * ny + m.vx * nx;
           if (dot > 0.5)
           {  m.vx -=  nx * dot;  m.vy -=  ny * dot;  }

        }//nexti  
        
      }//linetest  
        
        
      public function getMag(ax:Number, ay:Number):Number
      { return Math.sqrt(ax * ax + ay * ay); }
    
       public var closex:Number = 0;
       public var closey:Number = 0; 
       public function getClosePoint(px:Number, py:Number, a:xLine):Number
       {
          var t:Number;
          var ax:Number;            var ay:Number;
          var bx:Number;            var by:Number;
           
          ax = px - a.x0;       ay = py - a.y0;
          bx = a.x1 - a.x0;     by = a.y1 - a.y0;
          t = (ax*bx + ay*by) / (bx*bx + by*by);
          if (t < 0) { t = 0;}    if (t > 1) { t = 1; }
          
          closex = a.x0 + (a.x1 - a.x0) * t;
          closey = a.y0 + (a.y1 - a.y0) * t;
         return t;  
       }//getclose 

        
    }//classend
}

internal class xBall
{
  public var cx:Number = 0;  public var cy:Number = 0;
  public var vx:Number = 0;  public var vy:Number = 0;   
  public var rad:Number = 16;  
    
}//xball


internal class xLine
{
  public var x0:Number = 0;  public var y0:Number = 0;
  public var x1:Number = 0;  public var y1:Number = 0;
  
  public function xLine(ax:Number, ay:Number, bx:Number, by:Number)
  { x0 = ax; y0 = ay; x1 = bx; y1 = by; }
  
}//xline