外部テキストファイルをテキストフィールドに読み込む

/**
 * Copyright yun ( http://wonderfl.net/user/yun )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/DdJ9
 */

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.text.TextFormat;
    import flash.net.URLLoader;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.system.System;
    import flash.filters.DropShadowFilter;
    public class MyTextField extends Sprite {
        public var textLoader:URLLoader;
        public function MyTextField() {
            // 読み込むURL
            var urlReq:URLRequest = new URLRequest();
            urlReq.url = "http://oshige.com/flash/wfl/surfride.txt";
            // utfコードのテキストを読み込む場合はfalse（初期値）
            System.useCodePage = false;
            // URLLoaderクラスを使ってテキストデータを読み込む
            textLoader = new URLLoader();
            textLoader.addEventListener(Event.COMPLETE, completeHandler);
            // 読み込み開始
            textLoader.load(urlReq);
        }
        // 読み込み完了
        public function completeHandler(event:Event):void {
            var fld:TextField = creatTextField();
            // 読み込んだテキストデータをフィールドへ入れる
            fld.text = textLoader.data;
        }
        // テキストフィールドを作る
        public function creatTextField():TextField {
            // テキストの書式
            var tf:TextFormat = new TextFormat();
            tf.font = "_sans";
            tf.size = 14;
            tf.color = 0x333333;
            tf.leading = 5;
            // テキストフィールドの作成
            var fld:TextField = new TextField();
            fld.autoSize = TextFieldAutoSize.LEFT;
            fld.wordWrap = true;
            fld.width = 340;
            fld.x = 50;
            fld.y = 20;
            /*fld.background = true;
            fld.backgroundColor = 0xDDDDDD;*/
            fld.defaultTextFormat = tf;
            // ドロップシャドウフィルタを作って設定する
            var dsf:DropShadowFilter = new DropShadowFilter();
            dsf.alpha = 0.3;
            fld.filters = [dsf];
            addChild(fld);
            return fld;
        }
    }
}