forked from: SlideShow(Ken Burns Effect)

/**
 * Copyright vasari ( http://wonderfl.net/user/vasari )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/AjwB
 */

// forked from umhr's SlideShow(Ken Burns Effect)
/*
 * 
 * http://code.google.com/intl/ja/apis/picasaweb/docs/2.0/reference.html
*/
package {
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Loader;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.filters.DropShadowFilter;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.system.LoaderContext;
	import flash.system.Security;
	import flash.text.TextField;
	
	import org.libspark.betweenas3.BetweenAS3;
	import org.libspark.betweenas3.tweens.ITween;
	
	[SWF(backgroundColor="0x000000")]
	public class Main extends Sprite {
		private var data_array:Array;
		private var _loadCount:int;
		
		public function Main() {
			//左上、noScaleにして、ステージサイズの変更に対しては、
			//計算の値を変えることによって対応する。
			stage.align = "TL";
			stage.scaleMode = "noScale";
			stage.addEventListener(Event.RESIZE, onResize);
			
			//クロスドメインポリシーファイルの位置を指定
			Security.loadPolicyFile("http://photos.googleapis.com/data/crossdomain.xml");
			var myURLLoader:URLLoader = new URLLoader();
			myURLLoader.addEventListener(Event.COMPLETE, onComplete);
			//検索ワードを数種類の中からランダムに出るようにする。
			var keywords_array:Array = ["waterdrop", "red", "moon", "japan"];
			var keyword:String = keywords_array[Math.floor(Math.random() * 4)];
			//検索
			var URLstr:String = "http://photos.googleapis.com/data/feed/base/all?alt=rss&kind=photo&q="+keyword+"&imglic=commercial&max-results=8&imgmax=512";
			myURLLoader.load(new URLRequest(URLstr));
		}
		
		//画像読み込み後とステージのリサイズ時に実行
		private function onResize(e:Event = null):void {
			//画像読み込む前は実行されないようにdata_arrayの中身があるかのチェック
			if (data_array) {
				//縦横の短いほうもステージ一杯の大きさになる比率を求める
				for (var i:int = 0; i < data_array.length; i++) {
					data_array[i]["correction"] = Math.max(stage.stageWidth / data_array[i].width , stage.stageHeight / data_array[i].height);
				}
			}
		}
		
		private function onComplete(e:Event):void {
			//取得したデータをXML型に
			var myXML:XML = new XML(e.currentTarget.data);
			//namespaceを設定
			default xml namespace = new Namespace("http://search.yahoo.com/mrss/");
			data_array = [];
			//XMLをパース
			for (var i:int = 0; i < 8; i++) {
				//Objectをつくり、必要な値を入れている
				var data:Object = new Object();
				data["link"] = myXML.channel.item[i].link;
				data["credit"] = myXML.channel.item[i].group.credit;
				data["imgURL"] = myXML.channel.item[i].group.content.@url;
				
				//画像のロード
				var myLoader:Loader = new Loader();
				//クロスドメインポリシーファイルをドキュメントルートから取得
				var myLoaderContext:LoaderContext = new LoaderContext(true);
				myLoader.load(new URLRequest(data.imgURL), myLoaderContext);
				myLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, onCompleteImg);
				//loaderもObjectの中に
				data["loader"] = myLoader;
				
				//arrayに入れて、後から使いやすいように
				data_array[i] = data; 
			}
		}
		
		private function onCompleteImg(e:Event):void {
			//7回目までは処理が先に進まないように
			_loadCount ++;
			if (_loadCount < 8) {
				return;
			};
			
			//読み込んだ画像をdata_arrayにいれる。
			for (var i:int = 0; i < 8; i++) {
				//読み込んだ画像の幅と高さを取得しdata_arrayに入れる
				data_array[i]["width"] = data_array[i].loader.content.width;
				data_array[i]["height"] = data_array[i].loader.content.height;
				//読み込んだ画像が拡大しても荒れない処理のために一時bitmapdataにする
				var myBitmapData:BitmapData = new BitmapData(data_array[i].width, data_array[i].height);
				myBitmapData.draw(data_array[i].loader.content);
				//拡大しても荒れないようにsmoothをtrueに
				var smoothBitmap:Bitmap = new Bitmap(myBitmapData, "auto", true);
				data_array[i]["bitmap"] = smoothBitmap;
			}
			
			//画像ごとの最適な拡大比率を求める処理を実行
			onResize();
			
			//順次、画像をzoomする処理を設定
			var t:ITween = BetweenAS3.serial(
				BetweenAS3.delay(BetweenAS3.func(zoomTween, [data_array[0]]), 5, 0.1),
				BetweenAS3.delay(BetweenAS3.func(zoomTween, [data_array[1]]), 5, 0.1),
				BetweenAS3.delay(BetweenAS3.func(zoomTween, [data_array[2]]), 5, 0.1),
				BetweenAS3.delay(BetweenAS3.func(zoomTween, [data_array[3]]), 5, 0.1),
				BetweenAS3.delay(BetweenAS3.func(zoomTween, [data_array[4]]), 5, 0.1),
				BetweenAS3.delay(BetweenAS3.func(zoomTween, [data_array[5]]), 5, 0.1),
				BetweenAS3.delay(BetweenAS3.func(zoomTween, [data_array[6]]), 5, 0.1),
				BetweenAS3.delay(BetweenAS3.func(zoomTween, [data_array[7]]), 5, 0.1)
			);
			t = BetweenAS3.repeat(t, 99);
			//3秒目から実行
			t.gotoAndPlay(3);
		}
		
		//zoomする処理
		private function zoomTween(target:Object):void {
			//拡大率や中心位置を設定
			var scaleFrom:Number = target.correction;
			var scaleTo:Number = 1.1 * target.correction;
			var xFrom:Number = 0;
			var xTo:Number = 0;
			var yFrom:Number = 0;
			var yTo:Number = 0;
			//1/3の確立で右端が中心、中央が中心、左端が中心になるように
			if (Math.random() < 0.33) {
				xFrom = stage.stageWidth - scaleFrom * target.width;
				xTo = stage.stageWidth - scaleTo * target.width;
			}else if (Math.random() < 0.5) {
				xFrom = (stage.stageWidth - scaleFrom * target.width) * 0.5;
				xTo = (stage.stageWidth - scaleTo * target.width) * 0.5;
			}
			if (Math.random() < 0.33) {
				yFrom = stage.stageHeight - scaleFrom * target.height;
				yTo = stage.stageHeight - scaleTo * target.height;
			}else if (Math.random() < 0.5) {
				yFrom = (stage.stageHeight - scaleFrom * target.height) * 0.5;
				yTo = (stage.stageHeight - scaleTo * target.height) * 0.5;
			}
			//半分の確立で拡大／縮小の動きになるように
			if (Math.random() < 0.5) {
				var temp:Number = scaleFrom;
				scaleFrom = scaleTo;
				scaleTo = temp;
				temp = xFrom;
				xFrom = xTo;
				xTo = temp;
				temp = yFrom;
				yFrom = yTo;
				yTo = temp;
			}
			
			//クレジット＆リンクのためのテキストフィールドを作る。
			var textField:TextField = new TextField();
			textField.htmlText = "<a href='" + target.link + "'>Photo by " + target.credit + "</a>";
			textField.autoSize = "left";
			textField.textColor = 0xFFFFFF;
			//ドロップシャドウをかける
			textField.filters = [new DropShadowFilter()];
			
			//addChildして、フェードイン＆拡大して、remove
			BetweenAS3.serial(
				BetweenAS3.parallel(
					BetweenAS3.addChild(target.bitmap, this),
					BetweenAS3.addChild(textField, this)
				),
				BetweenAS3.parallel(
					BetweenAS3.tween(target.bitmap, { alpha:1 }, { alpha:0 }, 1),
					BetweenAS3.tween(target.bitmap, { x: xTo, y:yTo, scaleX:scaleTo, scaleY:scaleTo }, { x: xFrom, y: yFrom, scaleX:scaleFrom, scaleY:scaleFrom }, 6.1),
					BetweenAS3.tween(textField, { alpha:1 }, { alpha:0 }, 1)
				),
				BetweenAS3.parallel(
					BetweenAS3.removeFromParent(target.bitmap),
					BetweenAS3.removeFromParent(textField)
				)
			).play();
		}
	}
}