forked from: Comparing access speed to get a property of elements in an Array

/**
 * Copyright Fumio ( http://wonderfl.net/user/Fumio )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/9444
 */

// forked from Fumio's Comparing access speed to get a property of elements in an Array
package {
	import flash.display.Sprite;
	import flash.utils.getTimer;
	import flash.text.TextField;
	[SWF(width = "240",height = "180")]
	public class AccessingSprites extends Sprite {
		private const MAX_NUMBER:uint = 50000;
		private var started:int;
		private var my_txt:TextField = new TextField  ;
		private var label_txt:TextField = new TextField  ;
		public function AccessingSprites() {
			// Creating a TextField for display
			createTextField();
			// Starting Test
			useTypedVariable();
			directlyAccess();
			useVector();
		}
		private function useTypedVariable():void {
			var my_array:Array = getArray();
			started = getTimer();
			for (var i:uint = 0; i < MAX_NUMBER; i++) {
				var mySprite:Sprite = my_array[i];
				mySprite.rotation++;
			}
			xTrace(getTimer() - started);
		}
		private function directlyAccess():void {
			var my_array:Array = getArray();
			started = getTimer();
			for (var i:uint = 0; i < MAX_NUMBER; i++) {
				my_array[i].rotation++;
			}
			xTrace(getTimer() - started);
		}
		private function useVector():void {
			var myVector:Vector.<Sprite> = getVector();
			started = getTimer();
			for (var i:uint = 0; i < MAX_NUMBER; i++) {
				var mySprite:Sprite = myVector[i];
				mySprite.rotation++;
			}
			xTrace(getTimer() - started);
		}
		private function getArray():Array {
			var _array:Array = new Array();
			for (var i:uint = 0; i < MAX_NUMBER; i++) {
				_array[i] = new Sprite();
			}
			return _array;
		}
		private function getVector():Vector.<Sprite>  {
			var myVector:Vector.<Sprite> = new Vector.<Sprite>(MAX_NUMBER, true);
			for (var i:uint = 0; i < MAX_NUMBER; i++) {
				myVector[i] = new Sprite();
			}
			return myVector;
		}
		private function createTextField():void {
			addChild(my_txt);
			addChild(label_txt);
			my_txt.x +=  80;
			label_txt.text = "Array (typed):\nArray (direct):\nVector:";
		}
		private function xTrace(n:int):void {
			my_txt.appendText(String(n) + "\n");
		}
	}
}