forked from: [FLARToolkit]　マーカーに「蝶」がとまる (Butterfly Animation)

/**
 * Copyright tonsmart5 ( http://wonderfl.net/user/tonsmart5 )
 * GNU General Public License, v3 ( http://www.gnu.org/licenses/quick-guide-gplv3.html )
 * Downloaded from: http://wonderfl.net/c/93pX
 */

// forked from romatica's [FLARToolkit]　マーカーに「蝶」がとまる (Butterfly Animation)
// forked from romatica's FLARToolkitマーカー位置にイージング移動 (easing motion)
// forked from rokubou's FLARToolKit_Sample_Simple_PV3D
/**
 *-------------------------------------------------
 *
 *  FLARToolkit Butterfly Animation
 *
 * 　マーカーを認識すると、「蝶」がマーカーによってきて、とまります。
 * 　非認識だと、飛び立ちます。
 * 　認識中マーカーを極端に動かすと、飛び立ち、また、マーカー位置にとまります。
 *
 *　　TODO:
 *　　蝶のアニメーションもっと自然にしたい。
 *　　蝶のアニメーション動き部分、コードぐちゃぐちゃ。後で直す。
 *
 *　
 *　　認識中はマーカー位置に花とか表示するとよい？かも
 *
 *　　[marker pdf] マーカーをプリントしてください
 *　　www.romatica.com/dev/resource/flarlogo-marker.pdf
 * 
 *-------------------------------------------------
 */
 
package {
    import org.libspark.flartoolkit.core.FLARCode;
    import org.libspark.flartoolkit.core.param.FLARParam;
    import org.libspark.flartoolkit.core.raster.rgb.FLARRgbRaster_BitmapData;
    import org.libspark.flartoolkit.core.transmat.FLARTransMatResult;
    import org.libspark.flartoolkit.detector.FLARSingleMarkerDetector;
    import org.libspark.flartoolkit.support.pv3d.FLARBaseNode;
    import org.libspark.flartoolkit.support.pv3d.FLARCamera3D;
    import org.papervision3d.core.math.Matrix3D;
    import org.papervision3d.core.math.Number3D;
    import org.papervision3d.materials.BitmapMaterial;
    import org.papervision3d.objects.DisplayObject3D;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.render.LazyRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;

    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import flash.display.Loader;
    import flash.display.PixelSnapping;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.IOErrorEvent;
    import flash.events.SecurityErrorEvent;
    import flash.media.Camera;
    import flash.media.Video;
    import flash.net.URLLoader;
    import flash.net.URLLoaderDataFormat;
    import flash.net.URLRequest;
    import flash.system.LoaderContext;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.Dictionary;

    [SWF(width=640, height=480, backgroundColor=0x808080, frameRate=30)]

    /**
        * auther @itoz (http://www.romatica.com)
        */
    public class FLARToolkit_Butterfly extends Sprite {

        /**
         * FLAR
         */
        protected var canvasWidth : int;
        protected var canvasHeight : int;

        protected var captureWidth : int;
        protected var captureHeight : int;

        protected var codeWidth : int;

        protected var cameraParamFile : String;
        protected var markerPatternFile : String;

        private var urlLoader : URLLoader;

        protected var cameraParam : FLARParam;
        protected var markerPatternCode : FLARCode;

        protected var webCamera : Camera;

        protected var video : Video;

        private var capture : Bitmap;

        private var raster : FLARRgbRaster_BitmapData;

        private var detector : FLARSingleMarkerDetector;

        /**
         * PV3D
         */
        protected var scene : Scene3D;
        protected var viewport : Viewport3D;
        protected var camera3D : FLARCamera3D;
        protected var renderer : LazyRenderEngine;
        protected var markerNode : FLARBaseNode;

        protected var container : DisplayObject3D;

        private var _modelWRAP : DisplayObject3D;
        private var _hane1 : Bitmap;
        private var _hane2 : Bitmap;
        private var _lastRot : Number3D = new Number3D();
        private var loaderList : Dictionary;
        private var _loadCount : int = 0;
        //        private const loadURLArr : Array = [
        //                    "http://assets.wonderfl.net/images/related_images/a/a3/a321/a321a5037c6dbe4f496bbf4470a543190db4c840m",
        //                    "http://assets.wonderfl.net/images/related_images/0/0a/0ab3/0ab3a5daf0ce7e0df84abcfc28b7a411c2d66f28m"];
        private const loadURLArr : Array = ["http://www.romatica.com/dev/wonderfl/butterfly1.png",
"http://www.romatica.com/dev/wonderfl/butterfly2.png"];
        protected var _butt : DisplayObject3D;
        private const _stayLimit : int = 20;//蝶が飛び立つきっかけとなる目標点までの距離
        private var hane1 : Plane ;
        private var hane2 : Plane;
        //認識/非認識 表示
        private var _recognizer : TextField = new TextField()

        /**
         * Constructor
         * ここから初期化処理を呼び出して処理をスタート
         */
        public function FLARToolkit_Butterfly() {
    //Wonderfl.capture_delay(16);
            // 各種サイズの初期化
            captureWidth = 320;
            captureHeight = 240;
            canvasWidth = 640
            canvasHeight = 480;
            codeWidth = 80;
            
            // パラメータファイルの読込み
            // 今回は省略して初期値を用いる
            this.cameraParam = new FLARParam();
            this.cameraParam.changeScreenSize(captureWidth, captureHeight);
            
            // マーカーパターンファイルの読込み
            markerPatternFile = 'http://assets.wonderfl.net/static/flar/flarlogo.pat';
            this.urlLoader = new URLLoader();
            this.urlLoader.dataFormat = URLLoaderDataFormat.TEXT;
            this.urlLoader.addEventListener(Event.COMPLETE, this.onLoadCode);
            this.urlLoader.addEventListener(IOErrorEvent.IO_ERROR, dispatchEvent);
            this.urlLoader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, dispatchEvent);
            this.urlLoader.load(new URLRequest(markerPatternFile));
        }

        /**
         * マーカーパターンを読み込む
         * @param e Event
         */
        protected function onLoadCode(e : Event) : void {
            // URL Loader関連のイベントを削除
            this.urlLoader.removeEventListener(Event.COMPLETE, this.onLoadCode);
            
            // 分割数(縦・横)、黒枠の幅(縦・横)
            this.markerPatternCode = new FLARCode(16, 16, 50, 50);
            this.markerPatternCode.loadARPatt(this.urlLoader.data);
            // loaderがgc対象になるようにnullを突っ込む
            this.urlLoader = null;
     
            //画像読み込み
            laodImages();
        }

        //imege load start
        private function laodImages() : void {
            loaderList = new Dictionary();
            for (var i : int = 0;i < loadURLArr.length ;i++) {
                var loader : Loader = new Loader();
                loaderList[loader] = i;
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, completeHandler)
                loader.load(new URLRequest(loadURLArr[i]), new LoaderContext(true));
            }
        }

        private function completeHandler(event : Event) : void {
            var loader : Loader = event.target.content.parent as Loader;
            switch(loaderList[loader]) {
                case 0:
                    _hane1 = event.target.content as Bitmap;
                    break;
                case 1:
                    _hane2 = event.target.content as Bitmap;
                    break;
                default:
            }
            _loadCount++;
            if(_loadCount >= loadURLArr.length) {
                trace("LoadComplete")
                _allLoadComplete()
            }
        }

        /**
         * 画像ロード完了
         */
        private function _allLoadComplete() : void {
            // 初期化
            onInit();
        }

        /**
         * Webカメラの設定と、ARToolKitの準備
         */
        protected function onInit() : void {
            // setup webcam
            this.webCamera = Camera.getCamera();
            if (!this.webCamera) {
                throw new Error('No webcamera!');
            }
            this.webCamera.setMode(this.captureWidth, this.captureHeight, 30);
            
            this.video = new Video(this.captureWidth, this.captureHeight);
            this.video.attachCamera(this.webCamera);
            
            // setup ARToolKit
            this.capture = new Bitmap(new BitmapData(this.captureWidth, this.captureHeight, false, 0), PixelSnapping.AUTO, true);
            // ウェブカメラの解像度と表示サイズが異なる場合は拡大する
            this.capture.width = this.canvasWidth;
            this.capture.height = this.canvasHeight;
            this.addChild(this.capture);
            
            this.raster = new FLARRgbRaster_BitmapData(this.capture.bitmapData);
            // setup Single marker detector
            this.detector = new FLARSingleMarkerDetector(this.cameraParam, this.markerPatternCode, this.codeWidth);
            this.detector.setContinueMode(true);
            
            // PV3D
            this.viewport = this.addChild(new Viewport3D(this.captureWidth, this.captureHeight)) as Viewport3D;
            this.viewport.scaleX = this.canvasWidth / this.captureWidth;
            this.viewport.scaleY = this.canvasHeight / this.captureHeight;
            this.viewport.x = -4; // なぜかずれるので補正
            this.scene = new Scene3D();
            this.markerNode = this.scene.addChild(new FLARBaseNode(FLARBaseNode.AXIS_MODE_PV3D)) as FLARBaseNode;
            this.camera3D = new FLARCamera3D(this.cameraParam);
            this.renderer = new LazyRenderEngine(this.scene, this.camera3D, this.viewport);
            this.container = new DisplayObject3D();
            // モデルデータ
            this.setModelData();
            // モデルデータを登録
            this.markerNode.addChild(this.container);
            
            
            //認識非認識チェッカー
            _recognizer = new TextField();
            _recognizer.autoSize = TextFieldAutoSize.LEFT;
            _recognizer.background = true;
            _recognizer.backgroundColor = 0xcc0000;
            addChild(_recognizer);
            
            // start
            this.start();
            //
        }

        /**
         * モデルデータ作成
         */
        protected function setModelData() : void {
            _modelWRAP = new DisplayObject3D();
            _butt = new DisplayObject3D();
            //_butt.rotationX=90;
            //            var crynder:Cylinder=new Cylinder(new WireframeMaterial(0xcc0000),)
            //            _butt.addChild(crynder)
            var h1BMM : BitmapMaterial = new BitmapMaterial(_hane1.bitmapData)
            h1BMM.oneSide = false;
            var h2BMM : BitmapMaterial = new BitmapMaterial(_hane2.bitmapData)
            h2BMM.oneSide = false;
            hane1 = new Plane(h1BMM, 43, 61, 4, 6);
            hane2 = new Plane(h2BMM, 43, 61, 4, 6);
            _butt.addChild(hane1);
            _butt.addChild(hane2);
            hane1.transformVertices(Matrix3D.translationMatrix(21.5, 0, 0));
            hane2.transformVertices(Matrix3D.translationMatrix(-21.5, 0, 0));
            scene.addChild(_butt);
            _modelWRAP.addChild(_butt);
            scene.addChild(_modelWRAP);
        }

        
        /**
         * マーカーの認識と3次元モデルの描写を開始する
         */
        public function start() : void {
            // マーカー認識・非認識時用のイベントを登録
            this.addEventListener(MarkerEvent.MARKER_ADDED, this.onMarkerAdded);
            this.addEventListener(MarkerEvent.MARKER_UPDATED, this.onMarkerUpdated);
            this.addEventListener(MarkerEvent.MARKER_REMOVED, this.onMarkerRemoved);
            
            // 処理開始
            this.addEventListener(Event.ENTER_FRAME, this.run);
        }

        /**
         * 認識したマーカーの情報を格納
         */
        protected var resultMat : FLARTransMatResult = new FLARTransMatResult();

        public function onMarkerAdded(e : Event = null) : void {
            //          trace("[add]");
            _recognizer.text = "認識しています"
            _recognizer.backgroundColor = 0xffffff;
        }

        public function onMarkerUpdated(e : Event = null) : void {
        }

        public function onMarkerRemoved(e : Event = null) : void {
            _recognizer.text = "非認識"
            _recognizer.backgroundColor = 0xcc0000;
        }

        /**
         * 蝶の動き。
         * ここで処理振り分けを行っている
         */
        private var ang : Number = 0;
        private var _r : Number = 60;
        private var _spd : Number = 60;

        public function run(e : Event) : void {
            this.capture.bitmapData.draw(this.video);
            var rad : Number = ang / 180 * Math.PI;
            var rot : Number = Math.sin(rad);
            
            // Marker detect
            var detected : Boolean = false;
            try {
                detected = this.detector.detectMarkerLite(this.raster, 80) && this.detector.getConfidence() > 0.5;
            } catch (e : Error) {
            }
            
            // 認識時の処理
            if (detected) {
                detector.getTransformMatrix(this.resultMat);
                markerNode.setTransformMatrix(this.resultMat);
                var transform : Matrix3D = markerNode.transform;
                _lastRot = Matrix3D.matrix2euler(transform);
                this.dispatchEvent(new MarkerEvent(MarkerEvent.MARKER_ADDED));
            // 非認識時
            } else {
                
                this.dispatchEvent(new MarkerEvent(MarkerEvent.MARKER_REMOVED));
                markerNode.x += (rot * (Math.random() * 30 + 25));
                markerNode.y += (rot * Math.random() * 10 + 3);
                markerNode.z += (rot * (Math.random() * 10 + 10));
                                if(markerNode.y>100)markerNode.y-(Math.random()*10);            
                        }      
            //距離の絶対値＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿＿
            var _xAbs : Number = (markerNode.x - _modelWRAP.x);
            _xAbs = (_xAbs > 0) ? _xAbs : -_xAbs;
            var _yAbs : Number = (markerNode.y - _modelWRAP.y);
            _yAbs = (_yAbs > 0) ? _yAbs : -_yAbs;
            var _zAbs : Number = (markerNode.z - _modelWRAP.z);
            _zAbs = (_zAbs > 0) ? _zAbs : -_zAbs;
            
        
            
            if(_xAbs > _stayLimit || _yAbs > _stayLimit || _zAbs > _stayLimit) {
                _r = 60;
                ang += _spd;
                if(_butt.rotationX < 90)_butt.rotationX += 20;
                _butt.x += (rot * (Math.random() * 20));
                if(_butt.x > 10 )_butt.x = 10;
                if(_butt.x < -10 )_butt.x = -10;
                _butt.y += (rot * Math.random() * 25 + 20);
                if(_butt.y > 90 )_butt.y = 90;
                if(_butt.y < 0 )_butt.y = 0;
                _butt.z += (rot * ( Math.random() * 5 + 5));
                if(_butt.z > 20 )_butt.z = 20;
                if(_butt.z < -20 )_butt.z = -20;
            } else {
                _r = 30;
                ang += _spd / 11;
            }
            
            
            hane1.rotationY = rot * _r;
            hane2.rotationY = -(rot * _r)
                
                
            //イージング移動
            trace(rot)
            _modelWRAP.x += (markerNode.x - _modelWRAP.x) * 0.15;
            _modelWRAP.y += (markerNode.y - _modelWRAP.y) * 0.15;
            _modelWRAP.z += (markerNode.z - _modelWRAP.z) * 0.15;
            _modelWRAP.rotationX += (_lastRot.x - _modelWRAP.rotationX) * 0.1;
            _modelWRAP.rotationY += (_lastRot.y - _modelWRAP.rotationY) * 0.1;
            _modelWRAP.rotationZ += (_lastRot.z - _modelWRAP.rotationZ) * 0.1;
            //
            _butt.rotationX += (0 - _butt.rotationX) * 0.3;
            _butt.x += (0 - _butt.x) * 0.2;
            _butt.y += (0 - _butt.y) * 0.2;
            _butt.z += (0 - _butt.z) * 0.2;
            this.renderer.render();
        }
    }
}

import flash.events.Event;

/**
 * イベント制御用の簡易クラス
 */
class MarkerEvent extends Event {

    /**
     * Markerを認識した時
     */
    public static const MARKER_ADDED : String = "markerAdded";

    /**
     * Marker更新時
     */
    public static const MARKER_UPDATED : String = "markerUpdated";

    /**
     * Markerが認識しなくなった時
     */
    public static const MARKER_REMOVED : String = "markerRemoved";

    public function MarkerEvent(type : String, bubbles : Boolean = false, cancelable : Boolean = false) {
        super(type, bubbles, cancelable);
    }
}