flash on 2015-11-17

/**
 * Copyright mutantleg ( http://wonderfl.net/user/mutantleg )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/8YjB
 */

package {
    
    import flash.events.Event;
    import flash.display.Sprite;
    public class FlashTest extends Sprite {
        public function FlashTest() {
            
            vecRect = new Vector.<xRect>(0, false);
            var i:int; var a:xRect;
            for (i =0; i<64;i+=1)
            {
              a = new xRect();
               a.cx = Math.random()*430;
               a.cy = Math.random()*430;
               a.cw = Math.random()*30+8;
               a.ch = Math.random()*30+8;
    
               vecRect.push(a);  
            }//nexti

            a = new xRect(); vecRect.push(a); a.cx = 0; a.cy=0; a.cw=465;a.ch=8; 
            a = new xRect(); vecRect.push(a); a.cx = 0; a.cy=450; a.cw=465;a.ch=8; 
            a = new xRect(); vecRect.push(a); a.cx = 0; a.cy=0; a.cw=8;a.ch=465; 
            a = new xRect(); vecRect.push(a); a.cx = 450; a.cy=0; a.cw=8;a.ch=465; 
 
            
            myBall = new xBall();
             myBall.cx=230; myBall.cy=240;
            
            stage.addEventListener(Event.ENTER_FRAME, onEnter);
        }//ctor
        
          
        
        public var myBall:xBall;
        
        public var vecRect:Vector.<xRect>;
        
        public function onEnter(e:Event):void
        {
            var ms:Number;  var ta:Number;
            var a:xBall;      var d:Number;
            var mx:Number; var my:Number;
            mx = stage.mouseX; my = stage.mouseY;
            a = myBall;
            ta = Math.atan2(my-a.cy, mx-a.cx);
            d = getMag(mx-a.cx, my-a.cy);
            
             ms = 0.3;
            if (d < 30) {ms=0; a.vx*=0.9; a.vy*=0.9;}
            a.vx += Math.cos(ta)*ms;
            a.vy += Math.sin(ta) *ms;
            a.vx *= 0.99;  a.vy *= 0.99;
       
            rectTest(a);
            a.cx += a.vx;   a.cy += a.vy;
            
            
            graphics.clear();
            graphics.lineStyle(2, 0);
            graphics.drawCircle(a.cx, a.cy, a.rad);
 
            var i:int; var num:int; var w:xRect;           
            num = vecRect.length;      
            for (i = 0; i < num; i += 1)
            {
              w = vecRect[i];
              graphics.drawRect(w.cx,w.cy,w.cw,w.ch);
            }//nexti
                
        }//onenter
        
        
      public function rectTest(m:xBall):void
      {
        var i:int; var num:int; var a:xRect;
        var nx:Number; var ny:Number; var ta:Number;
        var d:Number; var dot:Number;    
        num=vecRect.length;
        for (i=0;i<num;i+=1)
        {
            a = vecRect[i];
           getClosePoint(m.cx,m.cy, a);
           d = getMag(m.cx-closex, m.cy-closey);
           if (d > m.rad) { continue; }
           
            ta = Math.atan2(closey - m.cy, closex - m.cx);
            m.cx += Math.cos(ta) * (d - m.rad);
            m.cy += Math.sin(ta) * (d - m.rad);
            nx = Math.cos(ta); ny = Math.sin(ta);  

           dot = m.vy * ny + m.vx * nx;
           if (dot > 0.5)
           {  m.vx -=  nx * dot;  m.vy -=  ny * dot;  }

        }//nexti  
        
      }//linetest  
        
        
      public function getMag(ax:Number, ay:Number):Number
      { return Math.sqrt(ax * ax + ay * ay); }
    
       public var closex:Number = 0;
       public var closey:Number = 0; 
       public function getClosePoint(px:Number, py:Number, a:xRect):void
       {
         var ix:Number; var iy:Number;
         if (px < a.cx) {ix = a.cx; }
         else if (px > a.cx+a.cw)  { ix = a.cx+ a.cw; }
         else {ix=px;}
         if (py < a.cy) {iy = a.cy; }
         else if (py > a.cy+a.ch)  { iy = a.cy+ a.ch; }
         else {iy=py;}
         closex =ix; closey=iy;
       }//getclose 

        
    }//classend
}

internal class xBall
{
  public var cx:Number = 0;  public var cy:Number = 0;
  public var vx:Number = 0;  public var vy:Number = 0;   
  public var rad:Number = 16;  
    
}//xball


internal class xRect
{
  public var cx:Number=8; public var cy:Number = 0;
  public var cw:Number=8; public var ch:Number = 0;

  
}//xRect