Project Euler 78

/**
 * Copyright uwi ( http://wonderfl.net/user/uwi )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/8TwU
 */

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.utils.getTimer;
    // @see http://projecteuler.net/index.php?section=problems&id=78
    // @see http://ja.wikipedia.org/wiki/%E6%95%B4%E6%95%B0%E5%88%86%E5%89%B2
    public class Euler78 extends Sprite {
        private var _tf : TextField;
  
        public function Euler78() {
            _tf = new TextField();
            _tf.width = 465;
            _tf.height = 465;
            addChild(_tf);
            
            var s : int = getTimer();
            _tf.appendText(solve().toString() + "\n");
            var g : int = getTimer();
            _tf.appendText((g - s).toString() + " ms\n");
        }
        
        private function solve() : int
        {
            var p : Array = [1];
            var k : int;
            var j : int;
            for(var n : int = 1;n < 100000;n++){
                var sum : Number = 0;
                var sg : int = 1;
                for(k = 1;(j = n - (3 * k * k - k) / 2) >= 0;k++){
                    sum += sg * p[j];
                    sg = -sg;
                }
                sg = 1;
                for(k = 1;(j = n - (3 * k * k + k) / 2) >= 0;k++){
                    sum += sg * p[j];
                    sg = -sg;
                }
                p[n] = sum % 1000000;
                if(p[n] == 0)return n;
//                _tf.appendText(p[n].toString() + "\n");
            }
            return -1;
        }
    }
}