forked from: forked from: Replacing string by using RegExp or String class only

/**
 * Copyright 9re ( http://wonderfl.net/user/9re )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/7lqE
 */

// forked from Fumio's forked from: Replacing string by using RegExp or String class only
// forked from Fumio's Replacing string by using RegExp or String class only
package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.text.TextFieldAutoSize;
    import flash.utils.getTimer;
    [SWF(width = "240",height = "180")]
    public class StringAndRegExpTest extends Sprite {
        private const COUNT:int = 10000;
        private const PI:Number = Math.PI;
        private var started:uint;
        private var my_txt:TextField = new TextField();
        private var label_txt:TextField = new TextField();
        public function StringAndRegExpTest() {
            // Creating a TextField for display
            createTextField();
            // Starting test
            var test_str:String = "すもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろすもももももももももももいろいろ";
            var find_str:String = "もも";
            var replace_str:String = "みみ";
            use_RegExp(test_str, find_str, replace_str);
            use_indexOf(test_str, find_str, replace_str);
            use_splitJoin(test_str, find_str, replace_str);
        }
        private function use_RegExp(test_str:String, find_str:String, replace_str:String):void {
            started = getTimer();
            for (var i:int = 0; i < COUNT; i++) {
                replaceBy_RegExp(test_str, find_str, replace_str);
            }
            xTrace(getTimer() - started);
        }
        private function use_indexOf(test_str:String, find_str:String, replace_str:String):void {
            started = getTimer();
            for (var i:int = 0; i < COUNT; i++) {
                replaceBy_indexOf(test_str, find_str, replace_str);
            }
            xTrace(getTimer() - started);
        }
        private function use_splitJoin(test_str:String, find_str:String, replace_str:String):void {
            started = getTimer();
            for (var i:int = 0; i < COUNT; i++) {
                replaceBy_joinSplit(test_str, find_str, replace_str);
            }
            xTrace(getTimer() - started);
        }
        private function replaceBy_RegExp(test_str:String, find_str:String, replace_str:String):void {
            var pattern:RegExp = new RegExp(find_str, "g");
            var result_str:String = test_str.replace(pattern,replace_str);
        }
        private function replaceBy_indexOf(test_str:String, find_str:String, replace_str:String):void {
            var numChar:uint = find_str.length;
            var end:uint;
            var result_str:String = "";
            for (var i:uint = 0; -1 < (end = test_str.indexOf(find_str, i)); i = end + numChar) {
                result_str +=  test_str.substring(i, end) + replace_str;
            }
            result_str +=  test_str.substring(i);
        }
        private function replaceBy_joinSplit(test_str:String, find_str:String, replace_str:String):void {
            var result_str:String = test_str.split(find_str).join(replace_str);
        }
        private function createTextField():void {
            addChild(my_txt);
            addChild(label_txt);
            my_txt.autoSize = TextFieldAutoSize.RIGHT;
            label_txt.autoSize = TextFieldAutoSize.LEFT;
            label_txt.text = "RegExp class:\nString class:\nSplit Join:";
        }
        private function xTrace(n:int):void {
            my_txt.appendText(String(n) + "\n");
        }
    }
}