Testing addChild() vs addChildAt(0) ver. 2

/**
 * Copyright Fumio ( http://wonderfl.net/user/Fumio )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/6IDi
 */

package {
	import flash.display.Sprite;
	import flash.utils.getTimer;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.text.TextFormat;
	import flash.text.TextFormatAlign;
        import flash.net.LocalConnection;
        import flash.system.System;
	[SWF(width = "240",height = "180")]
	public class Testing_addChildAt extends Sprite {
		private const AMOUNT:uint = 10000;
		private var my_txt:TextField = new TextField();
		private var label_txt:TextField = new TextField();
		private var my_fmt:TextFormat = new TextFormat();
		public function Testing_addChildAt() {
			// Creating a TextField for display
			createTextField();
			warmingUp();
			// Starting Test
			warmingUp();
			test_addChildAt();
			warmingUp();
			test_addChild();
			warmingUp();
			test_addChildAt();
			warmingUp();
			test_addChild();
		}
		private function test_addChild():void {
			var mySprite:Sprite = new Sprite();
			var nAmount:uint = AMOUNT;
			addChild(mySprite);
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var _sprite:Sprite = new Sprite();
				mySprite.addChild(_sprite);
			}
			xTrace("addChild()", getTimer() - started);
			removeChild(mySprite);
                        // gcHack();
		}
		private function test_addChildAt():void {
			var mySprite:Sprite = new Sprite();
			var nAmount:uint = AMOUNT;
			addChild(mySprite);
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var _sprite:Sprite = new Sprite();
				mySprite.addChildAt(_sprite, 0);
			}
			xTrace("addChildAt(0)", getTimer() - started);
			removeChild(mySprite);
                        // gcHack();
		}
		private function warmingUp():void {
			var mySprite:Sprite = new Sprite();
			var nAmount:uint = AMOUNT / 2;
			addChild(mySprite);
			var started:int = getTimer();
			for (var i:uint = 0; i < nAmount; i++) {
				var _sprite:Sprite = new Sprite();
				mySprite.addChild(_sprite);
				mySprite.addChildAt(_sprite, 0);
			}
			removeChild(mySprite);
                        gcHack();
		}
                private function gcHack():void {
                    try {
                        new LocalConnection().connect('test');
                        new LocalConnection().connect('test');
                    } catch (errorObject:Error) {}
                }
		private function createTextField():void {
			addChild(my_txt);
			addChild(label_txt);
			my_fmt.align = TextFormatAlign.RIGHT;
			my_txt.x +=  50;
			my_txt.defaultTextFormat = my_fmt;
			my_txt.autoSize = TextFieldAutoSize.RIGHT;
			label_txt.autoSize = TextFieldAutoSize.LEFT;
		}
		private function xTrace(_str:String,n:int):void {
			my_txt.appendText(String(n) + "\n");
			label_txt.appendText(_str + ":" + "\n");
		}
	}
}