Stardust [CircleContour]

/**
 * Copyright ProjectNya ( http://wonderfl.net/user/ProjectNya )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/4Bea
 */

////////////////////////////////////////////////////////////////////////////////
// Stardust [CircleContour]
//
// [AS3.0] Stardustを試すのだ！ (4)
// http://www.project-nya.jp/modules/weblog/details.php?blog_id=1716
////////////////////////////////////////////////////////////////////////////////

package {

    import flash.display.Sprite;
    import flash.events.Event;
    import flash.geom.Matrix;
    import flash.display.GradientType;
    import flash.display.SpreadMethod;
    import flash.display.InterpolationMethod;
    import idv.cjcat.stardust.Stardust;
    import idv.cjcat.stardust.common.clocks.SteadyClock;
    import idv.cjcat.stardust.common.initializers.Life;
    import idv.cjcat.stardust.common.initializers.Alpha;
    import idv.cjcat.stardust.common.math.UniformRandom;
    import idv.cjcat.stardust.common.actions.Age;
    import idv.cjcat.stardust.common.actions.DeathLife;
    import idv.cjcat.stardust.common.actions.ScaleCurve;
    import idv.cjcat.stardust.common.actions.AlphaCurve;
    import idv.cjcat.stardust.twoD.emitters.Emitter2D;
    import idv.cjcat.stardust.twoD.handlers.DisplayObjectHandler;
    import idv.cjcat.stardust.twoD.initializers.DisplayObjectClass;
    import idv.cjcat.stardust.twoD.initializers.Position;
    import idv.cjcat.stardust.twoD.initializers.Velocity;
    import idv.cjcat.stardust.twoD.zones.CircleContour;
    import idv.cjcat.stardust.twoD.zones.LazySectorZone;
    import idv.cjcat.stardust.twoD.actions.Accelerate;
    import idv.cjcat.stardust.twoD.actions.Move;

    [SWF(backgroundColor="#000000", width="465", height="465", frameRate="30")]

    public class Main extends Sprite {
        private var container:Sprite;
        private var emitter:Emitter2D;
        private var label:Label;
        private static var CR:String = String.fromCharCode(13);

        public function Main() {
            //Wonderfl.capture_delay(4);
            init();
        }

        private function init():void {
            draw();
            //
            label = new Label(100, 20, 20, Label.LEFT);
            addChild(label);
            label.x = 5;
            label.y = 440;
            label.textColor = 0xFFFFFF;
            label.alpha = 0.6;
            label.text = "Stardust";
            var version:Label = new Label(100, 14, 14, Label.LEFT);
            addChild(version);
            version.x = 100;
            version.y = 445;
            version.textColor = 0xFFFFFF;
            version.alpha = 0.6;
            version.text = "[" + Stardust.VERSION + "]";
            //
            setup();
        }
        private function setup():void {
            container = new Sprite();
            addChild(container);
            container.x = 232;
            container.y = 232;
            //
            var clock:SteadyClock = new SteadyClock(1);
            emitter = new Emitter2D(clock);
            emitter.particleHandler = new DisplayObjectHandler(container);
            //
            container.graphics.lineStyle(2, 0xFFFFFF, 0.2);
            container.graphics.drawCircle(0, 0, 60);
            //
            emitter.addInitializer(new DisplayObjectClass(Circle));
            emitter.addInitializer(new Position(new CircleContour(0, 0, 60)));
            emitter.addInitializer(new Velocity(new LazySectorZone(1, 0)));
            emitter.addInitializer(new Life(new UniformRandom(40, 0)));
            emitter.addInitializer(new Alpha(new UniformRandom(1, 0)));
            //
            emitter.addAction(new Age());
            emitter.addAction(new DeathLife());
            emitter.addAction(new Accelerate(0.2));
            emitter.addAction(new Move());
            emitter.addAction(new ScaleCurve(20, 10));
            emitter.addAction(new AlphaCurve(0, 10));
            //
            addEventListener(Event.ENTER_FRAME, update, false, 0, true);
        }
        private function update(evt:Event):void {
            emitter.step();
        }
        private function draw():void {
            var colors:Array = [0x00AAE4, 0x0069A0];
            var alphas:Array = [1, 1];
            var ratios:Array = [0, 255];
            var matrix:Matrix = new Matrix();
            matrix.createGradientBox(464, 464, 0, 0, 0);
            graphics.beginGradientFill(GradientType.RADIAL, colors, alphas, ratios, matrix, SpreadMethod.PAD, InterpolationMethod.RGB, 0);
            graphics.drawRect(0, 0, 465, 465);
            graphics.endFill();
        }

    }

}




//////////////////////////////////////////////////
// Circleクラス
//////////////////////////////////////////////////

import flash.display.Sprite;

internal class Circle extends Sprite {
    private static var color:uint = 0xFFFFFF;

    public function Circle() {
        init();
    }

    private function init():void {
        graphics.beginFill(color, 0.5);
        graphics.drawCircle(0, 0, 16);
        graphics.beginFill(color, 1);
        graphics.drawCircle(0, 0, 8);
        graphics.endFill();
    }

}


//////////////////////////////////////////////////
// Labelクラス
//////////////////////////////////////////////////

import flash.display.Sprite;
import flash.text.TextField;
import flash.text.TextFieldType;
import flash.text.TextFieldAutoSize;
import flash.text.AntiAliasType;
import flash.text.TextFormat;
import flash.text.TextFormatAlign;

class Label extends Sprite {
    private var txt:TextField;
    private static var fontType:String = "_ゴシック";
    private var _width:uint = 20;
    private var _height:uint = 20;
    private var size:uint = 12;
    public static const LEFT:String = TextFormatAlign.LEFT;
    public static const CENTER:String = TextFormatAlign.CENTER;
    public static const RIGHT:String = TextFormatAlign.RIGHT;

    public function Label(w:uint, h:uint, s:uint = 12, align:String = LEFT) {
        _width = w;
        _height = h;
        size = s;
        draw(align);
    }

    private function draw(align:String):void {
        txt = new TextField();
        addChild(txt);
        txt.width = _width;
        txt.height = _height;
        txt.autoSize = align;
        txt.type = TextFieldType.DYNAMIC;
        txt.selectable = false;
        //txt.embedFonts = true;
        //txt.antiAliasType = AntiAliasType.ADVANCED;
        var tf:TextFormat = new TextFormat();
        tf.font = fontType;
        tf.size = size;
        tf.align = align;
        txt.defaultTextFormat = tf;
        textColor = 0x000000;
    }
    public function set text(param:String):void {
        txt.text = param;
    }
    public function set textColor(param:uint):void {
        txt.textColor = param;
    }

}