Project Euler 173

/**
 * Copyright uwi ( http://wonderfl.net/user/uwi )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/2NdL
 */

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.utils.getTimer;
    // @see http://projecteuler.net/index.php?section=problems&id=173
    // a:外周1辺, k:内周1辺(k >= 1), N:使用タイル数 とすると、
    // a^2 - (a-2k)^2 <= N かつ a-2k >= 1
    // 3 <= a <= sqrt(N)のときは後者の条件しか使われず、
    // sqrt(N) < a <= N/4 + 1のときは前者の条件しか使われない。
    public class Euler173 extends Sprite {
        private var _tf : TextField;
  
        public function Euler173() {
            _tf = new TextField();
            _tf.width = 465;
            _tf.height = 465;
            addChild(_tf);
            
            var s : int = getTimer();
            _tf.appendText(solve().toString() + "\n");
            var g : int = getTimer();
            _tf.appendText((g - s).toString() + " ms\n");
        }
        
        private const N : int = 1000000;
        
        private function solve() : int
        {
            var bound : int = Math.sqrt(N);
            var ret : int = 0;
            var a : int;
            for(a = 3;a <= bound;a++){
                ret += (a - 1) >> 1;
            }
            for(a = bound + 1;a <= N / 4 + 1;a++){
                ret += (a - Math.sqrt(a * a - N)) >> 1;
            }
            
            return ret;
        }
    }
}