forked from: ひよこちゃん ゆらゆら

/**
 * Copyright kururu99 ( http://wonderfl.net/user/kururu99 )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/18PD
 */

// forked from ProjectNya's ひよこちゃん ゆらゆら
////////////////////////////////////////////////////////////////////////////////
// ひよこちゃん ゆらゆら
////////////////////////////////////////////////////////////////////////////////

package {

    import flash.display.Sprite;
    import flash.display.MovieClip;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.system.Security;

    [SWF(backgroundColor="#FFFFFF", width="465", height="465", frameRate="30")]

    public class Main extends Sprite {
        private static var basePath:String = "http://assets.wonderfl.net/images/related_images/";
        private static var sunshinePath:String = "9/9b/9bbe/9bbec77d53bddc5e7a5f2c00abbade6bd641c549";
        private var loader:PiyoLoader;
        private static var piyoPath:String = "http://www.project-nya.jp/images/flash/piyo.swf";
        private var piyo:MovieClip;
        private var box:Box;
        private static var radius:uint = 15;
        private static var radian:Number = Math.PI/180;
        private static var speed:uint = 5;

        public function Main() {
            //Wonderfl.disable_capture();
            Wonderfl.capture_delay(4);
            init();
        }

        private function init():void {
            var sky:Sky = new Sky(465, 350);
            addChild(sky);
            var ground:Ground = new Ground(465, 115);
            addChild(ground);
            ground.y = 350;
            var sun:Sun = new Sun(100);
            addChild(sun);
            sun.x = 10;
            sun.y = 10;
            var shine:PhotoLoader = new PhotoLoader();
            addChild(shine);
            shine.alpha = 0.5;
            shine.load(basePath + sunshinePath);
            box = new Box(120, 180);
            box.init(0xFFFFFF, 0x990000);
            addChild(box);
            box.x = 232;
            box.y = 420;
            loader = new PiyoLoader();
            loader.addEventListener(PiyoLoader.COMPLETE, complete, false, 0, true);
            loader.load(piyoPath);
        }
        private function complete(evt:Event):void {
            loader.removeEventListener(PiyoLoader.COMPLETE, complete);
            piyo = loader.content;
            addChild(piyo);
            piyo.x = box.x;
            piyo.y = box.y - 180 - 120*0.12;
            piyo.scaleX = piyo.scaleY = 2;
            loader = null;
            piyo.velocity = 0;
            piyo.angle = 0;
            piyo.addEventListener(Event.ENTER_FRAME, swing, false, 0, true);
        }
        private function swing(evt:Event):void {
            piyo.piyo.rotation = piyo.velocity;
            piyo.velocity = radius*Math.sin(piyo.angle*radian);
            piyo.angle += speed;
        }

    }

}


import flash.display.Sprite;
import flash.display.MovieClip;
import flash.display.Loader;
import flash.display.LoaderInfo;
import flash.net.URLRequest;
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.events.HTTPStatusEvent;
import flash.events.SecurityErrorEvent;
import flash.system.Security;
import flash.system.LoaderContext;

class PiyoLoader extends Sprite {
    private var loader:Loader;
    private var info:LoaderInfo;
    public var content:MovieClip;
    public static const IO_ERROR:String = IOErrorEvent.IO_ERROR;
    public static const HTTP_STATUS:String = HTTPStatusEvent.HTTP_STATUS;
    public static const SECURITY_ERROR:String = SecurityErrorEvent.SECURITY_ERROR;
    public static const INIT:String = Event.INIT;
    public static const COMPLETE:String = Event.COMPLETE;

    public function PiyoLoader() {
        Security.allowDomain("www.project-nya.jp");
        loader = new Loader();
        info = loader.contentLoaderInfo;
    }

    public function load(file:String):void {
        info.addEventListener(IOErrorEvent.IO_ERROR, ioerror, false, 0, true);
        info.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpstatus, false, 0, true);
        info.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityerror, false, 0, true);
        info.addEventListener(Event.INIT, initialize, false, 0, true);
        info.addEventListener(Event.COMPLETE, complete, false, 0, true);
        try {
            loader.load(new URLRequest(file), new LoaderContext(true));
        } catch (err:Error) {
            trace(err.message);
        }
    }
    public function unload():void {
        loader.unload();
    }
    private function ioerror(evt:IOErrorEvent):void {
        loader.unload();
        dispatchEvent(new Event(PiyoLoader.IO_ERROR));
    }
    private function httpstatus(evt:HTTPStatusEvent):void {
        dispatchEvent(new Event(PiyoLoader.HTTP_STATUS));
    }
    private function securityerror(evt:SecurityErrorEvent):void {
        dispatchEvent(new Event(PiyoLoader.SECURITY_ERROR));
    }
    private function initialize(evt:Event):void {
        content = MovieClip(info.content);
        dispatchEvent(new Event(PiyoLoader.INIT));
    }
    private function complete(evt:Event):void {
        info.removeEventListener(IOErrorEvent.IO_ERROR, ioerror);
        info.removeEventListener(HTTPStatusEvent.HTTP_STATUS, httpstatus);
        info.removeEventListener(SecurityErrorEvent.SECURITY_ERROR, securityerror);
        info.removeEventListener(Event.INIT, initialize);
        info.removeEventListener(Event.COMPLETE, complete);
        //addChild(loader);
        dispatchEvent(new Event(PiyoLoader.COMPLETE));
    }

}


import flash.display.Shape;
import flash.geom.Matrix;
import flash.display.GradientType;

class Sky extends Shape {
    private static var _width:uint;
    private static var _height:uint;
    private static var color1:uint = 0x3F68AB;
    private static var color2:uint = 0x77B2EE;

    public function Sky(w:uint, h:uint) {
        _width = w;
        _height = h;
        draw();
    }

    private function draw():void {
        var colors:Array = [color1, color2];
        var alphas:Array = [1, 1];
        var ratios:Array = [0, 255];
        var matrix:Matrix = new Matrix();
        matrix.createGradientBox(_width, _height, 0.5*Math.PI, 0, 0);
        graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, matrix);
        graphics.drawRect(0, 0, _width, _height);
        graphics.endFill();
    }

}


import flash.display.Shape;
import flash.geom.Matrix;
import flash.display.GradientType;

class Ground extends Shape {
    private static var _width:uint;
    private static var _height:uint;
    private static var color1:uint = 0x99CC33;
    private static var color2:uint = 0x7EB133;

    public function Ground(w:uint, h:uint) {
        _width = w;
        _height = h;
        draw();
    }

    private function draw():void {
        var colors:Array = [color1, color2];
        var alphas:Array = [1, 1];
        var ratios:Array = [0, 255];
        var matrix:Matrix = new Matrix();
        matrix.createGradientBox(_width, _height, 0.5*Math.PI, 0, 0);
        graphics.beginGradientFill(GradientType.LINEAR, colors, alphas, ratios, matrix);
        graphics.drawRect(0, 0, _width, _height);
        graphics.endFill();
    }

}


import flash.display.Shape;
import flash.geom.Matrix;
import flash.display.GradientType;

class Sun extends Shape {
    private static var radius:uint;
    private static var color:uint = 0xFFFFFF;

    public function Sun(r:uint) {
        radius = r;
        draw();
    }

    private function draw():void {
        var colors:Array = [color, color, color];
        var alphas:Array = [1, 0.3, 0];
        var ratios:Array = [25, 102, 231];
        var matrix:Matrix = new Matrix();
        matrix.createGradientBox(radius*2, radius*2, 0, -radius, -radius);
        graphics.beginGradientFill(GradientType.RADIAL, colors, alphas, ratios, matrix);
        graphics.drawCircle(0, 0, radius);
        graphics.endFill();
    }

}


import flash.display.Sprite;
import flash.display.Loader;
import flash.display.LoaderInfo;
import flash.net.URLRequest;
import flash.events.Event;
import flash.events.IOErrorEvent;
import flash.events.HTTPStatusEvent;
import flash.events.SecurityErrorEvent;
import flash.display.Bitmap;
import flash.system.LoaderContext;

class PhotoLoader extends Sprite {
    private var loader:Loader;
    private var info:LoaderInfo;
    public var content:Bitmap;
    private var smoothing:Boolean;
    public static const IO_ERROR:String = IOErrorEvent.IO_ERROR;
    public static const HTTP_STATUS:String = HTTPStatusEvent.HTTP_STATUS;
    public static const SECURITY_ERROR:String = SecurityErrorEvent.SECURITY_ERROR;
    public static const INIT:String = Event.INIT;
    public static const COMPLETE:String = Event.COMPLETE;

    public function PhotoLoader() {
        loader = new Loader();
        info = loader.contentLoaderInfo;
    }

    public function load(file:String, s:Boolean = false):void {
        smoothing = s;
        info.addEventListener(IOErrorEvent.IO_ERROR, ioerror, false, 0, true);
        info.addEventListener(HTTPStatusEvent.HTTP_STATUS, httpstatus, false, 0, true);
        info.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityerror, false, 0, true);
        info.addEventListener(Event.INIT, initialize, false, 0, true);
        info.addEventListener(Event.COMPLETE, complete, false, 0, true);
        try {
            loader.load(new URLRequest(file), new LoaderContext(true));
        } catch (err:Error) {
            trace(err.message);
        }
    }
    public function unload():void {
        loader.unload();
    }
    private function ioerror(evt:IOErrorEvent):void {
        loader.unload();
        dispatchEvent(new Event(PhotoLoader.IO_ERROR));
    }
    private function httpstatus(evt:HTTPStatusEvent):void {
        dispatchEvent(new Event(PhotoLoader.HTTP_STATUS));
    }
    private function securityerror(evt:SecurityErrorEvent):void {
        dispatchEvent(new Event(PhotoLoader.SECURITY_ERROR));
    }
    private function initialize(evt:Event):void {
        content = Bitmap(info.content);
        if (smoothing) content.smoothing = true;
        dispatchEvent(new Event(PhotoLoader.INIT));
    }
    private function complete(evt:Event):void {
        info.removeEventListener(IOErrorEvent.IO_ERROR, ioerror);
        info.removeEventListener(HTTPStatusEvent.HTTP_STATUS, httpstatus);
        info.removeEventListener(SecurityErrorEvent.SECURITY_ERROR, securityerror);
        info.removeEventListener(Event.INIT, initialize);
        info.removeEventListener(Event.COMPLETE, complete);
        addChild(loader);
        dispatchEvent(new Event(PhotoLoader.COMPLETE));
    }

}


import flash.display.Sprite;
import flash.display.Shape;
import frocessing.color.ColorHSV;
import flash.geom.Matrix;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.InterpolationMethod;

class Box extends Sprite {
    private var _width:uint;
    private var _height:uint;
    private var tColor:uint = 0xFFFFFF;
    private var fColor:uint = 0xFFFFFF;

    public function Box(w:uint, h:uint) {
        _width = w;
        _height = h;
    }

    public function init(t:uint = 0xFFFFFF, f:uint = 0xFFFFFF):void {
        tColor = t;
        fColor = f;
        draw();
    }
    private function draw():void {
        var top:Shape = new Shape();
        addChild(top);
        top.graphics.beginFill(tColor);
        top.graphics.moveTo(-_width*0.5, -_height);
        top.graphics.lineTo(-_width*0.36, -_height-_width*0.24);
        top.graphics.lineTo(_width*0.36, -_height-_width*0.24);
        top.graphics.lineTo(_width*0.5, -_height);
        top.graphics.endFill();
        var light:ColorHSV = new ColorHSV();
        light.value = fColor;
        light.v = 1.2;
        var dark:ColorHSV = new ColorHSV();
        dark.value = fColor;
        dark.v = 0.4;
        var front:Shape = new Shape();
        addChild(front);
        var colors:Array = [light.value, dark.value];
        var alphas:Array = [1, 1];
        var ratios:Array = [0, 255];
        var matrix:Matrix = new Matrix();
        var offset:Number = _width*0.05;
        matrix.createGradientBox(_width*2, _width*2, 0, -_width*1.5+offset, -_height-_width+offset);
        front.graphics.beginGradientFill(GradientType.RADIAL, colors, alphas, ratios, matrix, SpreadMethod.PAD, InterpolationMethod.RGB, 0);
        front.graphics.drawRect(-_width*0.5, -_height, _width, _height);
        front.graphics.endFill();
    }

}