Project Euler 134

/**
 * Copyright uwi ( http://wonderfl.net/user/uwi )
 * MIT License ( http://www.opensource.org/licenses/mit-license.php )
 * Downloaded from: http://wonderfl.net/c/168a
 */

package {
    import flash.display.Sprite;
    import flash.text.TextField;
    import flash.utils.getTimer;
    // @see http://projecteuler.net/index.php?section=problems&id=134
    public class Euler134 extends Sprite {
        private var _tf : TextField;
  
        public function Euler134() {
            _tf = new TextField();
            _tf.width = 465;
            _tf.height = 465;
            addChild(_tf);
            
            var s : int = getTimer();
            _tf.appendText("" + solve(1000000) + "\n");
            _tf.appendText("" + Number(N) + "\n");
            var g : int = getTimer();
            _tf.appendText("" + (g - s) + " ms\n");
        }
        
        private const N : Number = 1000000000000;
        
        // Numberの範囲におさまらないとかｗｗｗｗｗ
        private function solve(n : int) : Array
        {
            var sum : Number = 0;
            var sumu : Number = 0;
            var primes : Array = doEratosthenes(n + 100);
            for(var i : int = 0;i < primes.length;i++){
                if(primes[i] < 5 || primes[i] > n)continue;
                for(var ten : int = 1;ten <= primes[i];ten *= 10);
                var invten : Number = invP(ten, primes[i + 1]);
                var x : Number = ((primes[i + 1] - primes[i]) * invten) % primes[i + 1];
                var s : Number = ten * x + primes[i];
//                _tf.appendText("" + primes[i] + "\t" + primes[i + 1] + "\t" + s + "\n");
                sum += s;
                sumu += int(sum / N);
                sum %= N;
            }
            return [sumu, sum];
        }
        
        // Fermat's Little Theorem
        // a * a^(p-2) = 1 (mod p)
        private function invP(a : int, p : int) : Number
        {
            var ret : Number = 1;
            var mul : Number = a;
            for(var c : uint = p - 2;c > 0;c >>>= 1){
                if((c & 1) == 1){
                    ret *= mul;
                    ret %= p;
                }
                mul *= mul;
                mul %= p;
            }
            return ret;
        }
        
        private static function doEratosthenes(n : int) : Array
        {
            var ar : Vector.<int> = new Vector.<int>(n / 2 - 1);
            var i : int;
            for(i = 0;i < ar.length;i++)ar[i] = 1;
            
            var sq : int = (Math.sqrt(n) - 3) >> 1;
            for(var p : int = 0;p <= sq;p++){
                if(ar[p] == 1){
                    var m : int = 2 * p + 3;
                    for(var mm : int = m * m;mm <= n;mm += 2 * m){
                        ar[(mm - 3) >> 1] = 0;
                    }
                }
            }
            var ret : Array = [2];
            for(i = 0;i < ar.length;i++){
                if(ar[i] == 1)ret.push(2 * i + 3);
            }
            return ret;
        }
        
    }
}